AlliedModders - VIP Core (by R1KO) module implementation sample

Somebody asked me to show a minimal but fully safe example of template to implement VIP Core by R1KO to any custom plugin to become a module of it.

So, here it is.

Features:

VIP Core is fully optional (you can compile with or without vip_core.inc).
Safely tracking dynamic Core library loading/unloading.
Tracking VIP Player loading/unloading/adding/removing.
Supports listening for VIP internal "sm_reload_vip_cfg" command to populate data according to contents of groups.ini file.
Translation support.

Spoiler

PHP Code:


		
			
#define PLUGIN_VERSION                 "1.0"

#pragma semicolon 1
#pragma newdecls required

#include <sourcemod>
#undef REQUIRE_PLUGIN
#tryinclude <vip_core>

#define VIP_FEATURE_NAME            "YOUR_FEATURE_ALIAS"        // change it into unique alias and place it in vip groups.ini file
#define CVAR_FLAGS                     FCVAR_NOTIFY

public Plugin myinfo =
{
    name         = "VIP Core (by R1KO) optional implementation template example",
    author         = "Alex Dragokas",
    description = "Provides a snippet to check whether current player has a VIP feature enabled considering all the access checks.",
    version     = PLUGIN_VERSION,
    url         = "https://forums.alliedmods.net/member.php?u=282667"
};

bool g_bLateload, g_bVipFeatureEnabled[MAXPLAYERS+1]; // g_bVipFeatureEnabled is a final variable telling you whether client has access to a feature.

#if defined _vip_core_included
    bool g_bVipAvail;
#else
    #pragma unused g_bLateload
#endif

public APLRes AskPluginLoad2(Handle myself, bool late, char[] error, int err_max) 
{
    g_bLateload = late;
    return APLRes_Success;
}

public void OnPluginStart()
{
    LoadTranslations("vip_sample.phrases"); // you must provide appropriate translations for "VIP_Feature_Title"
    
    RegConsoleCmd("sm_check", CmdCheck, "Answers are VIP feature enabled for you");
    
    #if defined _vip_core_included
        
        AddCommandListener(CmdReloadConfig, "sm_reload_vip_cfg");
    
        if( LibraryExists("vip_core") )
        {
            g_bVipAvail = true;
        }
        
        if( g_bVipAvail )
        {
            if( VIP_IsVIPLoaded() )
            {
                VIP_OnVIPLoaded();
            }
        }
    #endif
}

public Action CmdCheck(int client, int argc)
{
    PrintToChat(client, "Feature enabled? %s", g_bVipFeatureEnabled[client] ? "Yes" : "No");
    return Plugin_Handled;
}

public void OnLibraryAdded(const char[] name)
{
    #if defined _vip_core_included
    
    if( strcmp(name, "vip_core") == 0 )
    {
        g_bVipAvail = true;
    }
    #endif
}

public void OnLibraryRemoved(const char[] name)
{
    #if defined _vip_core_included

    if( strcmp(name, "vip_core") == 0 )
    {
        g_bVipAvail = false;
    }
    #endif
}

public void OnPluginEnd()
{
    #if defined _vip_core_included
        
        if( CanTestFeatures() && GetFeatureStatus(FeatureType_Native, "VIP_UnregisterFeature") == FeatureStatus_Available )
        {
            if( VIP_IsValidFeature(VIP_FEATURE_NAME) )
            {
                VIP_UnregisterFeature(VIP_FEATURE_NAME);
            }
        }
    #endif
}

public void OnClientPutInServer(int client)
{
    #if defined _vip_core_included
        g_bVipFeatureEnabled[client] = false;
    #endif
}

#if defined _vip_core_included

public void VIP_OnFeatureRegistered(const char[] szFeature)
{
    if( g_bLateload && strcmp(szFeature, VIP_FEATURE_NAME) == 0 )
    {
        for( int i = 1; i <= MaxClients; i++ )
        {
            if( IsClientInGame(i) )
            {
                UpdatePlayerFeatureVIP(i);
            }
        }
    }
}

public Action CmdReloadConfig(int client, const char[] sCommand, int iArg)
{
    ConVar cvar = FindConVar("sm_vip_admin_flag");
    if( cvar )
    {
        char flags[32];
        cvar.GetString(flags, sizeof(flags));
        if( GetUserFlagBits(client) & ReadFlagString(flags) == 0 )
            return Plugin_Continue;
    }
    CreateTimer(1.0, Timer_ReloadConfig);
    return Plugin_Continue;
}

public Action Timer_ReloadConfig(Handle timer)
{
    for( int i = 1; i <= MaxClients; i++ )
    {
        if( IsClientInGame(i) && !IsFakeClient(i) )
        {
            UpdatePlayerFeatureVIP(i);
        }
    }
}

public void VIP_OnVIPClientLoaded(int client)
{
    UpdatePlayerFeatureVIP(client);
}

void UpdatePlayerFeatureVIP(int client)
{
    if( g_bVipAvail )
    {
        if( VIP_IsClientVIP(client) )
        {
            g_bVipFeatureEnabled[client] = VIP_IsClientFeatureUse(client, VIP_FEATURE_NAME);
        }
        else {
            g_bVipFeatureEnabled[client] = false;
        }
    }
}

public void VIP_OnVIPLoaded()
{
    if( !VIP_IsValidFeature(VIP_FEATURE_NAME) )
    {
        VIP_RegisterFeature(VIP_FEATURE_NAME,     BOOL,     _,         OnToggleItemCallback, OnDisplayItem_Vip_Feature);
    }
}

public Action OnToggleItemCallback(int client, const char[] sFeatureName, VIP_ToggleState OldStatus, VIP_ToggleState &NewStatus)
{
    g_bVipFeatureEnabled[client] = (NewStatus == ENABLED);
    return Plugin_Continue;
}

public bool OnDisplayItem_Vip_Feature(int client, const char[] sFeatureName, char[] sDisplay, int maxlen)
{
    FormatEx(sDisplay, maxlen, "%T [%T]", "VIP_Feature_Title", client, VIP_IsClientFeatureUse(client, VIP_FEATURE_NAME) ? "Enabled": "Disabled", client);
    return true;
}
#endif

Translation file:

Code:

"Phrases"

{

        "Enabled"

        {

                "en"                "Enabled"

                "ru"                "Включено"

        }

        "Disabled"

        {

                "en"                "Disabled"

                "ru"                "Выключено"

        }

        "VIP_Feature_Title"

        {

                "en"                "Title of your test feature"

                "ru"                "Заголовок тестовой фичи"

        }

}

Installation:
- Install VIP Core by R1KO: https://github.com/R1KO/VIP-Core
- Compile the sample plugin (Note: vip_core.inc file must be located in "include" dir of your local compiler in order to make the plugin be a module of VIP Core.
- Specify line:

Code:

"YOUR_FEATURE_ALIAS" "1"

in the file /addons/sourcemod/data/vip/cfg/groups.ini for the appropriate VIP Group.
- Enter in console sm_reload_vip_cfg or reboot the server.

Internal VIP commands:

PHP Code:


		
			
!vip
// opens a VIP Core menu to select/unselect your favorite VIP features.

// e.t.c., read VIP own's documentation in the inc file.

Sample commands:

PHP Code:


		
			
!check
// Answers, are VIP feature enabled for you, considering all the access checks and your preferables.

Good luck!