AlliedModders
Page 1 of 17 1 2311 Last »
Show 40 post(s) from this thread on one page

AlliedModders (https://forums.alliedmods.net/index.php)
-   Suggestions / Requests (https://forums.alliedmods.net/forumdisplay.php?f=12)
-   -   Connections Counter (https://forums.alliedmods.net/showthread.php?t=121138)

xakintosh 03-12-2010 04:46
Connections Counter
 
Here is my idea if someone know how to do it make it here :)

Count player connections and store in database.
If user have 100 connections => newbie
If user have 500 connections => semi-pro
If user have 750 connections => pro
If user have 1000 connections => veteran
-------------------------------------------------
Chat => [Veteran]Nickname
Scoretab => [Veteran]Nickname
Connect => Nickname is veterean in this server
-------------------------------------------------

xakintosh 03-12-2010 05:16
Re: Connections Counter
 
Hey thank you :)

lazarev 03-12-2010 06:39
Re: Connections Counter
 
[EDIT] - 0.0.6: Added [Admin] tag
PHP Code:
#include < amxmodx >
#include < amxmisc >
#include < cstrike >
#include < nvault >

new const VERSION[] = "0.0.6";
new const PREFIX[] = "[CC] ";

new Connects[ 33 ];
new szConnectStatus[ 33 ][ 9 ];

new g_iMsgSayText;
new g_vSaveFile;

new iPlayers[ 33 ][ 32 ];
new iNum[ 33 ];

public plugin_init()
{
    register_plugin( "Connections Counter", VERSION, "Juice" );
    
    register_cvar( "connects_count", VERSION, FCVAR_SERVER | FCVAR_SPONLY ); 
    
    register_clcmd( "say", "HookSay" );
    register_clcmd( "say_team", "HookSay_Team" );
    
    g_iMsgSayText = get_user_msgid( "SayText" );
    
    g_vSaveFile = nvault_open( "ConnectCount" );
}

public client_putinserver( id )
{
    if( !is_user_bot( id ) )
    {
        if( task_exists( id ) )
        {
            remove_task( id );
        }
        
        LoadData( id );
        ++Connects[ id ];
        
        if ( is_user_admin( id ) )
        {
            szConnectStatus[ id ] = "Admin";
        }
        else 
        {
            if( Connects[ id ] <= 100 ) 
            {
                szConnectStatus[ id ] = "Newbie";
            }
            else if( 100 < Connects[ id ] <= 500 )
            {
                szConnectStatus[ id ] = "Semi-Pro";
            }
            else if( 500 < Connects[ id ] <= 750 )
            {
                szConnectStatus[ id ] = "Pro";
            }
            else if( Connects[ id ] > 750 ) 
            {
                szConnectStatus[ id ] = "Veteran";
            }
        }
        set_task( 2.0, "PrintZ0r", id ); 
    }
}

public PrintZ0r( id )
{
    new szName[ 33 ];
    new szMessage[ 256 ];
    get_user_name( id, szName, 32 );
    format( szMessage, 255, "^x04%s^x03%s have joined with^x04 %i^x03 Connections. [^x04Status: %s^x03]", PREFIX, szName, Connects[ id ], szConnectStatus[ id ] );
    Print( 0, 1, szMessage )
}

public client_disconnect( id ) 
{  
    if( !is_user_bot( id ) )
    {
        SaveData( id );
        if( task_exists( id ) )
        {
            remove_task( id );
        }
    }
}  

public SaveData( id ) 
{ 
    new szAuthID[ 35 ];
    new vaultkey[ 33 ], vaultdata[ 13 ]; 
    
    get_user_authid( id, szAuthID, 34 );
    
    format( vaultkey, 32, "%s", szAuthID );
    format( vaultdata, 12," %i ", Connects[ id ] ); 

    nvault_set( g_vSaveFile, vaultkey, vaultdata ); 
    
    return PLUGIN_CONTINUE; 
}  

public LoadData( id ) 
{ 
    new szAuthID[ 35 ]; 
    new vaultkey[ 33 ], vaultdata[ 13 ];
    new ConnectCount[ 33 ];
    
    get_user_authid( id, szAuthID, 34 ); 
    
    format( vaultkey, 32, "%s", szAuthID ); 
    format( vaultdata, 12," %i ", Connects[ id ] ); 
    
    nvault_get( g_vSaveFile, vaultkey, vaultdata, 255 ); 
    
    parse( vaultdata, ConnectCount, 32); 
    
    Connects[ id ] = str_to_num( ConnectCount ); 
    
    return PLUGIN_CONTINUE; 
}  

public HookSay( id )
{
    new szMessage[ 192 ];
    read_args( szMessage, 191 );
    remove_quotes( szMessage );
    
    new szName[ 33 ];
    get_user_name( id, szName, 32 );
    
    if ( szMessage[0] == '@' || szMessage[0] == '/' || szMessage[0] == '!' || equal (szMessage, "") )
    {
        return PLUGIN_CONTINUE;
    }
    
    if ( is_user_alive( id ) )
    {
        format( szMessage, 255, "^x04[%s]^x03 %s^x01 :  %s", szConnectStatus[ id ], szName, szMessage );
        Print(0, id, szMessage)
    }
    else if ( cs_get_user_team( id ) != CS_TEAM_SPECTATOR )
    {
        format( szMessage, 255, "^x04[%s]^x01 *DEAD*^x03 %s^x01 :  %s", szConnectStatus[ id ], szName, szMessage );
        Print(0, id, szMessage)
    }
    else 
    {
        format( szMessage, 255, "^x04[%s]^x01 *SPEC*^x03 %s^x01 :  %s", szConnectStatus[ id ], szName, szMessage );
        Print(0, id, szMessage)
    }
    return PLUGIN_HANDLED;
}

public HookSay_Team( id )
{
    new szMessage[ 192 ];
    read_args( szMessage, 191 );
    remove_quotes( szMessage );
    
    new szName[ 33 ], szTeam[ 33 ];
    get_user_name( id, szName, 32 );
        
    new CsTeams:userteam = cs_get_user_team( id );
        
    if ( szMessage[0] == '@' || szMessage[0] == '/' || szMessage[0] == '!' || equal( szMessage, "" ) )
    {
        return PLUGIN_CONTINUE;
    }
    
    if ( userteam == CS_TEAM_T )
    {
        get_players( iPlayers[ id ], iNum[ id ], _, "TERRORIST" );
        szTeam = "(Terrorist)";
    }
    else if ( userteam == CS_TEAM_CT )
    {
        get_players( iPlayers[ id ], iNum[ id ], _, "CT" );
        szTeam = "(Counter-Terrorists)";
    }
    else
    {
        get_players( iPlayers[ id ], iNum[ id ], _, "SPECTATOR" );
        szTeam = "(Spectator)";
    }
    for ( new a = 0; a < iNum[ id ]; ++a )
    {
        new i = iPlayers[ id ][ a ];
        if( cs_get_user_team( i ) != userteam )
        {
            return PLUGIN_HANDLED;
        }
        
        if ( is_user_alive( id ) )
        {
            format( szMessage, 255, "^x04[%s]^x01 %s^x03 %s^x01 :  %s", szConnectStatus[ id ], szTeam, szName, szMessage );
            Print( i, id, szMessage )
        }
        else if (!is_user_alive(id) && userteam != CS_TEAM_SPECTATOR)
        {
            format( szMessage, 255, "^x04[%s]^x01 *DEAD* %s^x03 %s^x01 :  %s", szConnectStatus[ id ], szTeam, szName, szMessage );
            Print( i, id, szMessage )
        }
        else
        {
            format( szMessage, 255, "^x04[%s]^x01 %s^x03 %s^x01 :  %s", szConnectStatus[ id ], szTeam, szName, szMessage );
            Print( i, id, szMessage )
        }
    }
    return PLUGIN_HANDLED;
}

Print( id, colorid, szMessage[], any:... )
{
    message_begin( id ? MSG_ONE_UNRELIABLE : MSG_BROADCAST, g_iMsgSayText, _, id );
    write_byte( colorid );
    write_string( szMessage );
    message_end( );
} 
servers running this plugin lol

xakintosh 03-12-2010 12:38
Re: Connections Counter
 
very good thanks again !

lazarev 03-12-2010 12:59
Re: Connections Counter
 
np, any suggestions? :mrgreen:

xakintosh 03-12-2010 13:48
Re: Connections Counter
 
Maybe you can combine with this plugin http://forums.alliedmods.net/showthread.php?p=878874
If user have 100 connections => Veteran to can choose join/leaver messages ;]

lazarev 03-12-2010 14:38
Re: Connections Counter
 
[EDIT] This version Saves leave message:
PHP Code:
#include < amxmodx >
#include < amxmisc >
#include < cstrike >
#include < nvault >

new const VERSION[] = "0.0.8";
new const PREFIX[] = "[CC] ";

new Connects[ 33 ];
new szConnectStatus[ 33 ][ 9 ];

new g_iMsgSayText;
new g_vSaveFile;

new iPlayers[ 33 ][ 32 ];
new iNum[ 33 ];

new g_szLeaveMessage[ 33 ][ 64 ];

new bool:g_bVeteran[ 33 ];

public plugin_init()
{
    register_plugin( "Advanced Connections Counter", VERSION, "Juice" );
    
    register_cvar( "connects_count", VERSION, FCVAR_SERVER | FCVAR_SPONLY ); 
    
    register_clcmd( "say", "HookSay" );
    register_clcmd( "say_team", "HookSay_Team" );
    
    g_iMsgSayText = get_user_msgid( "SayText" );
    
    g_vSaveFile = nvault_open( "ConnectCount" );
}

public client_putinserver( id )
{
    if( !is_user_bot( id ) )
    {
        if( task_exists( id ) )
        {
            remove_task( id );
        }
        
        LoadData( id );
        ++Connects[ id ];
        
        if ( is_user_admin( id ) )
        {
            szConnectStatus[ id ] = "Admin";
            g_bVeteran[ id ] = true;
        }
        else 
        {
            if( Connects[ id ] <= 100 ) 
            {
                szConnectStatus[ id ] = "Newbie";
            }
            else if( 100 < Connects[ id ] <= 500 )
            {
                szConnectStatus[ id ] = "Semi-Pro";
            }
            else if( 500 < Connects[ id ] <= 750 )
            {
                szConnectStatus[ id ] = "Pro";
            }
            else if( Connects[ id ] > 750 ) 
            {
                szConnectStatus[ id ] = "Veteran";
                g_bVeteran[ id ] = true;
            }
        }
        set_task( 2.0, "PrintZ0r", id ); 
    }
}

public PrintZ0r( id )
{
    new szName[ 33 ], szMessage[ 128 ];
    get_user_name( id, szName, 32 );
    format( szMessage, 127, "^x04%s^x03%s have joined with^x04 %i^x03 Connections. [^x04Status: %s^x03]", PREFIX, szName, Connects[ id ], szConnectStatus[ id ] );
    Print( 0, 1, szMessage )
}

public client_disconnect( id ) 
{  
    if( !is_user_bot( id ) )
    {
        new szName[ 33 ], szMessage[ 128 ];
        get_user_name( id, szName, 32 );
        SaveData( id );
        
        if( g_bVeteran[ id ] )
        {
            format( szMessage, 127, "^x04%s^x03Veteran: %s has left the server. [^x04Message: %s^x03]", PREFIX, szName, g_szLeaveMessage[ id ] );
            Print( 0, 1, szMessage )
            g_bVeteran[ id ] = false;
        }
        else 
        {
            g_szLeaveMessage[ id ] = " ";
        }
        if( task_exists( id ) )
        {
            remove_task( id );
        }
    }
}  

public SaveData( id ) 
{ 
    new szAuthID[ 20 ];
    new vaultkey[ 20 ], vaultdata[ 128 ]; 
    
    get_user_authid( id, szAuthID, 19 );
    
    format( vaultkey, 19, "%s", szAuthID );
    format( vaultdata, 127, " %i %s ", Connects[ id ], g_szLeaveMessage[ id ] ); 

    nvault_set( g_vSaveFile, vaultkey, vaultdata ); 
    
    return PLUGIN_CONTINUE; 
}  

public LoadData( id ) 
{ 
    new szAuthID[ 20 ]; 
    new vaultkey[ 20 ], vaultdata[ 128 ];
    new ConnectCount[ 33 ];
    new LeaveMsg[ 64 ];
    
    get_user_authid( id, szAuthID, 19 ); 
    
    format( vaultkey, 19, "%s", szAuthID ); 
    format( vaultdata, 127, " %i %s ", Connects[ id ], g_szLeaveMessage[ id ] ); 
    
    nvault_get( g_vSaveFile, vaultkey, vaultdata, 127 ); 
    
    parse( vaultdata, ConnectCount, 32, LeaveMsg, 63 ); 
    
    Connects[ id ] = str_to_num( ConnectCount ); 
    g_szLeaveMessage[ id ] = LeaveMsg;
    
    return PLUGIN_CONTINUE; 
}  

public HookSay( id )
{
    new szMessage[ 257 ];
    read_args( szMessage, 256 );
    remove_quotes( szMessage );
    
    new szName[ 33 ];
    get_user_name( id, szName, 32 );
    
    if( g_bVeteran[ id ] )
    {
        if( szMessage[ 0 ] == '/' && szMessage[ 2 ] == 'e' && szMessage[ 4 ] == 'v' && szMessage[ 6 ] == 'm' )
        {
            new Arg[ 64 ];
            strbreak( szMessage, szMessage, 95, Arg, 63 );
            remove_quotes( Arg );
        
            if( !Arg[ 0 ] )
            {
                if( g_szLeaveMessage[ id ][ 0 ] )
                {
                    client_print( id, print_chat, "%sYour current leave message is ^"%s^"", PREFIX, g_szLeaveMessage[ id ] );
                }
                else
                {
                    client_print( id, print_chat, "%sYou haven't set a leave message yet. To do so, type /leavemsg ^"message^".", PREFIX );
                }
            }
        
            else if( equali( Arg, "remove" ) )
            {
                g_szLeaveMessage[ id ] = "No Message Set";
                client_print( id, print_chat, "%sYour leave message was removed.", PREFIX )
            }
            else
            {
                copy( g_szLeaveMessage[ id ], 63, Arg )
                client_print( id, print_chat, "%sYour leave message has been set to ^"%s^"", PREFIX, Arg );
            }
            return PLUGIN_CONTINUE;
        }
    }
    
    if ( szMessage[0] == '@' || szMessage[0] == '/' || szMessage[0] == '!' || equal (szMessage, "") )
    {
        return PLUGIN_CONTINUE;
    }
    
    if ( is_user_alive( id ) )
    {
        format( szMessage, 255, "^x04[%s]^x03 %s^x01 :  %s", szConnectStatus[ id ], szName, szMessage );
        Print(0, id, szMessage)
    }
    else if ( cs_get_user_team( id ) != CS_TEAM_SPECTATOR )
    {
        format( szMessage, 255, "^x04[%s]^x01 *DEAD*^x03 %s^x01 :  %s", szConnectStatus[ id ], szName, szMessage );
        Print(0, id, szMessage)
    }
    else 
    {
        format( szMessage, 255, "^x04[%s]^x01 *SPEC*^x03 %s^x01 :  %s", szConnectStatus[ id ], szName, szMessage );
        Print(0, id, szMessage)
    }
    return PLUGIN_HANDLED;
}

public HookSay_Team( id )
{
    new szMessage[ 257 ];
    read_args( szMessage, 256 );
    remove_quotes( szMessage );
    
    new szName[ 33 ], szTeam[ 33 ];
    get_user_name( id, szName, 32 );
        
    new CsTeams:userteam = cs_get_user_team( id );

    if ( szMessage[0] == '@' || szMessage[0] == '/' || szMessage[0] == '!' || equal( szMessage, "" ) )
    {
        return PLUGIN_CONTINUE;
    }
    
    if ( userteam == CS_TEAM_T )
    {
        get_players( iPlayers[ id ], iNum[ id ], _, "TERRORIST" );
        szTeam = "(Terrorist)";
    }
    else if ( userteam == CS_TEAM_CT )
    {
        get_players( iPlayers[ id ], iNum[ id ], _, "CT" );
        szTeam = "(Counter-Terrorists)";
    }
    else
    {
        get_players( iPlayers[ id ], iNum[ id ], _, "SPECTATOR" );
        szTeam = "(Spectator)";
    }
    for ( new a = 0; a < iNum[ id ]; ++a )
    {
        new i = iPlayers[ id ][ a ];
        if( cs_get_user_team( i ) != userteam )
        {
            return PLUGIN_HANDLED;
        }
        
        if ( is_user_alive( id ) )
        {
            format( szMessage, 255, "^x04[%s]^x01 %s^x03 %s^x01 :  %s", szConnectStatus[ id ], szTeam, szName, szMessage );
            Print( i, id, szMessage )
        }
        else if (!is_user_alive(id) && userteam != CS_TEAM_SPECTATOR)
        {
            format( szMessage, 255, "^x04[%s]^x01 *DEAD* %s^x03 %s^x01 :  %s", szConnectStatus[ id ], szTeam, szName, szMessage );
            Print( i, id, szMessage )
        }
        else
        {
            format( szMessage, 255, "^x04[%s]^x01 %s^x03 %s^x01 :  %s", szConnectStatus[ id ], szTeam, szName, szMessage );
            Print( i, id, szMessage )
        }
    }
    return PLUGIN_HANDLED;
}

Print( id, colorid, szMessage[], any:... )
{
    message_begin( id ? MSG_ONE_UNRELIABLE : MSG_BROADCAST, g_iMsgSayText, _, id );
    write_byte( colorid );
    write_string( szMessage );
    message_end( );
} 

xakintosh 03-12-2010 23:55
Re: Connections Counter
 
You are the best dude ever http://www.pic4ever.com/images/2.gif I own you one :)

Bugsy 03-13-2010 01:13
Re: Connections Counter
 
Just a few things you should correct:

1. You should not call any functions on a player at client_disconnect() because there are times when the player will already be gone when this is called. It is better to cache a players name and steam-id into global strings; this solves the disconnect problem and it also saves you numerous native calls. You may notice that you do not run into any errors while testing but your plugin will occasionally error when left running.

2. In SaveData() you are retrieving the users authid into szAuthID and then copying it to vaultkey for your nvault_set() call. Why not just use szAuthID as your key?

3. formatex() should be used instead of format().

4. In LoadData you are formatting vaultdata with the users data but then read data from vault into this string. This makes no sense because you format the string with data just to immediately over-write it with data read from vault.

5. You can call remove_task without calling task_exists.

6. iPlayers[] can be defined locally in HookSay_Team() since it is not used anywhere else in plugin.

7. Calling get_players() with a team name but without flag "e" which tells it you want to pass a team name. See http://www.amxmodx.org/funcwiki.php?go=func&id=174

8. nVault never closed. Add plugin_end() and call nvault_close().

There may be more but I'm tired.

Optional, but you can do something like this to make variables and code neater:
PHP Code:
enum StatusLevels
{
    Newbie,
    SemiPro,
    Pro,
    Veteran
}

new const szStatus[][] = 
{
    "Newbie",
    "Semi-Pro",
    "Pro",
    "Veteran"
}

new const iStatusLevels[][] = 
{
    { 0 , 100 },
    { 101 , 500 },
    { 501 , 750 },
    { 751 , 99999 }
}

enum PlayerData
{
    Name[ 33 ],
    AuthID[ 35 ],
    Connections,
    Status,
    JoinMsg[ 128 ],
    LeaveMsg[ 128 ]
}

new g_PData[ 33 ][ PlayerData ];

get_user_name( id , g_PData[ id ][ Name ] , charsmax( g_PData[] ) );
get_user_authid( id , g_PData[ id ][ AuthID ] , charsmax( g_PData[] ) ); 

xakintosh 03-13-2010 09:49
Re: Connections Counter
 
Maybe you can add playtime ? :)


All times are GMT -4. The time now is 19:07.
Page 1 of 17 1 2311 Last »
Show 40 post(s) from this thread on one page

Powered by vBulletin®
Copyright ©2000 - 2024, vBulletin Solutions, Inc.