AlliedModders - How to remove 'kill' sound

AlliedModders (https://forums.alliedmods.net/index.php)

- Suggestions / Requests (https://forums.alliedmods.net/forumdisplay.php?f=12)

- - How to remove 'kill' sound (https://forums.alliedmods.net/showthread.php?t=193170)

How to remove 'kill' sound

Hello,
how can I remove 'kill' sound?

Explain:
When player write kill in the console, he dies and run sound. I want to remove this sound. How?

Re: How to remove 'kill' sound

Code:

#include <amxmodx>
#include <fakemeta>

new g_die_sounds[][] =
{
    "player/die1.wav",
    "player/die2.wav",
    "player/die3.wav",
    "player/death6.wav"
};
    

public plugin_precache()
{
    register_plugin( "Block die sound", "1.0", "matsi" );
    register_forward( FM_EmitSound, "FwdEmitSound" );
}

public FwdEmitSound( const entity, const channel, const sound[], const Float:volume, const Float:attenuation, const flags, const pitch )
{
    for( new i; i < sizeof g_die_sounds; i ++ )
    {
        if( equal( sound, g_die_sounds[ i ] ) )
        return FMRES_SUPERCEDE;
    }
    return FMRES_IGNORED;
}

I'm not sure if thats the correct way to do it or if there are all the sounds you wanted to be blocked. :oops:

But try it. :attack:

Re: How to remove 'kill' sound

Thank you, this works, but is there more short way?

Re: How to remove 'kill' sound

Short way? What is wrong with this way?

Re: How to remove 'kill' sound

Little optimazation.

PHP Code:


		
			
#include <amxmodx>
#include <fakemeta>

new Trie:g_tBlockPlayersSounds

new g_iMaxPlayers
#define IsPlayer(%0)    ( 1 <= %0 <= g_iMaxPlayers )
    
public plugin_precache()
{
    register_plugin( "Block die sound", "1.1", "matsi" );
    
    register_forward( FM_EmitSound, "FwdEmitSound" );

    new die_sounds[][] =
    {
        "player/die1.wav",
        "player/die2.wav",
        "player/die3.wav",
        "player/death6.wav"
    };
    g_tBlockPlayersSounds = TrieCreate();
    for(new i; i<sizeof(die_sounds); i++)
    {
        TrieSetCell(g_tBlockPlayersSounds, die_sounds[i], 1);
    }

    g_iMaxPlayers = get_maxplayers();
}

public FwdEmitSound( const entity, const channel, const sound[] /* , const Float:volume, const Float:attenuation, const flags, const pitch */ )
{
    if( IsPlayer(entity) && TrieKeyExists(g_tBlockPlayersSounds, sound) )
    {
        return FMRES_SUPERCEDE;
    }
    return FMRES_IGNORED;
}