AlliedModders - Weird bug in Counter-Strike: Source

AlliedModders (https://forums.alliedmods.net/index.php)

- Source Servers (SRCDS) (https://forums.alliedmods.net/forumdisplay.php?f=130)

- - Weird bug in Counter-Strike: Source – Night vision gives ammo (https://forums.alliedmods.net/showthread.php?t=326823)

Weird bug in Counter-Strike: Source – Night vision gives ammo

You buy a night vision via the buy menu (or even 'buy nvgs'). After that you get full ammo for your primary and secondary weapon.

Can someone confirm this bug?

Re: Weird bug in Counter-Strike: Source – Night vision gives ammo

Quote:

Originally Posted by ElooKoN (Post 2714687)

You buy a night vision via the buy menu (or even 'buy nvgs'). After that you get full ammo for your primary and secondary weapon.

Can someone confirm this bug?

Have you tried it without sourcemod/metamod running?

Re: Weird bug in Counter-Strike: Source – Night vision gives ammo

Yes. Don't you have this bug? It should work on every server.

Re: Weird bug in Counter-Strike: Source – Night vision gives ammo

Quote:

Originally Posted by ElooKoN (Post 2714722)

Yes. Don't you have this bug? It should work on every server.

how bout on listen server?
maybe check your key bind?

Re: Weird bug in Counter-Strike: Source – Night vision gives ammo

Seems it does buy ammo when purchade nvgs. bug
Happens also when buy kevlar/armor

Re: Weird bug in Counter-Strike: Source – Night vision gives ammo

Quote:

Originally Posted by Bacardi (Post 2714909)

Seems it does buy ammo when purchade nvgs. bug
Happens also when buy kevlar/armor

You're right, I tested it. That is very unfavorable, I wonder why nobody noticed this bug before.

Any way to fix this using a custom game patch? Otherwise the only solution would be to store/restore the values before/after buying I think.

Re: Weird bug in Counter-Strike: Source – Night vision gives ammo

Was looking... source code.

Seems when use command buy item/weapon,
all weapons, item_kevlar(vest), item_assaultsuit(vesthelm), item_nvgs(nvgs) are using this function, except item_defuser

PHP Code:


		
			
CCSPlayer::GiveNamedItem( const char *pszName, int iSubType )

...which will StockPlayerAmmo( pWeapon ); at end of code.

if StockPlayerAmmo( pWeapon ); fail find entity as CWeaponCSBase, for example nvgs+vesthelm+vest,
it will then refill both, primary and secondary weapons ammo :(

This also happen to all items (nvgs, vest, vesthelm, defuser) with command give and SourceMod function GivePlayerItem,
it will refill primary and secondary weapons ammo.

But if those items are created by ent_create, it won't stock ammo.

---------------

I tried made plugin but I don't have time. There is many ways to get ammo (buyammo1, buyammo2, cl_rebuy "PrimaryWeapon PrimaryAmmo Defuser Armor HEGrenade Flashbang SmokeGrenade SecondaryWeapon SecondaryAmmo NightVision" and so on).

not perfect

PHP Code:


		
			

#include <sdktools>

Handle timers[MAXPLAYERS];


public void OnPluginStart()
{
    //AddCommandListener(cmd, "buy");
    HookEventEx("item_pickup", item_pickup);
    //RegConsoleCmd("sm_armor", armor);
}

public Action armor(int client, int args)
{

    return Plugin_Handled;
}

public Action cmd(int client, char[] command, args)
{
    if(client == 0 || !IsClientInGame(client) || GetClientTeam(client) < 2 || !IsPlayerAlive(client))    return Plugin_Continue;

    char buffer[10];
    GetCmdArg(1, buffer, sizeof(buffer));

    if(StrEqual(buffer, "nvgs", false) ||
    StrEqual(buffer, "vest", false) ||
    StrEqual(buffer, "vesthelm", false))
    {
        if(timers[client] != null) return Plugin_Continue;
    
        int primary = GetPlayerWeaponSlot(client, 0);
        int secondary = GetPlayerWeaponSlot(client, 1);

        int primary_ammo_type = -1;
        int primary_ammo = -1;
        int primary_clip = -1;
        int secondary_ammo_type = -1;
        int secondary_ammo = -1;
        int secondary_clip = -1;

        if(primary != -1)
        {
            primary_ammo_type = GetEntProp(primary, Prop_Send, "m_iPrimaryAmmoType");
            primary_ammo = GetEntProp(client, Prop_Send, "m_iAmmo", _, primary_ammo_type);
            primary_clip = GetEntProp(primary, Prop_Send, "m_iClip1");
            PrintToServer("item_pickup primary %i %i", primary_ammo, primary_clip);
        }

        if(secondary != -1)
        {
            secondary_ammo_type = GetEntProp(secondary, Prop_Send, "m_iPrimaryAmmoType");
            secondary_ammo = GetEntProp(client, Prop_Send, "m_iAmmo", _, secondary_ammo_type);
            secondary_clip = GetEntProp(secondary, Prop_Send, "m_iClip1");
            PrintToServer("item_pickup secondary %i %i", secondary_ammo, secondary_clip);
        }

        DataPack pack;
        timers[client] = CreateDataTimer(1.0, delay, pack);
        pack.WriteCell(client);
        pack.WriteCell(GetClientUserId(client));
        pack.WriteCell(primary);
        pack.WriteCell(primary_ammo_type);
        pack.WriteCell(primary_ammo);
        pack.WriteCell(primary_clip);
        pack.WriteCell(secondary);
        pack.WriteCell(secondary_ammo_type);
        pack.WriteCell(secondary_ammo);
        pack.WriteCell(secondary_clip);
        pack.Reset();
    }



    return Plugin_Continue;
}

public void item_pickup(Event event, char[] name, bool dontBroadcast)
{
/*
    item_pickup
    userid       short   2
    item         string  usp
*/
    int userid = event.GetInt("userid");

    char item[10];
    event.GetString("item", item, sizeof(item));

    if(StrEqual(item, "nvgs", false) ||
    StrEqual(item, "vest", false) ||
    StrEqual(item, "vesthelm", false))
    {
        int client = GetClientOfUserId(userid);
        
        
        if(timers[client] != null) return;
        
        
        int primary = GetPlayerWeaponSlot(client, 0);
        int secondary = GetPlayerWeaponSlot(client, 1);

        int primary_ammo_type = -1;
        int primary_ammo = -1;
        int primary_clip = -1;
        int secondary_ammo_type = -1;
        int secondary_ammo = -1;
        int secondary_clip = -1;

        if(primary != -1)
        {
            primary_ammo_type = GetEntProp(primary, Prop_Send, "m_iPrimaryAmmoType");
            primary_ammo = GetEntProp(client, Prop_Send, "m_iAmmo", _, primary_ammo_type);
            primary_clip = GetEntProp(primary, Prop_Send, "m_iClip1");
            PrintToServer("item_pickup primary %i %i", primary_ammo, primary_clip);
        }

        if(secondary != -1)
        {
            secondary_ammo_type = GetEntProp(secondary, Prop_Send, "m_iPrimaryAmmoType");
            secondary_ammo = GetEntProp(client, Prop_Send, "m_iAmmo", _, secondary_ammo_type);
            secondary_clip = GetEntProp(secondary, Prop_Send, "m_iClip1");
            PrintToServer("item_pickup secondary %i %i", secondary_ammo, secondary_clip);
        }

        DataPack pack;
        timers[client] = CreateDataTimer(1.0, delay, pack);
        pack.WriteCell(GetClientOfUserId(userid));
        pack.WriteCell(userid);
        pack.WriteCell(primary);
        pack.WriteCell(primary_ammo_type);
        pack.WriteCell(primary_ammo);
        pack.WriteCell(primary_clip);
        pack.WriteCell(secondary);
        pack.WriteCell(secondary_ammo_type);
        pack.WriteCell(secondary_ammo);
        pack.WriteCell(secondary_clip);
        pack.Reset();
    }
}

public Action delay(Handle timer, DataPack pack)
{
    int index = pack.ReadCell();
    int client = GetClientOfUserId(pack.ReadCell());
    timers[index] = null;

    if(client == 0 || !IsClientInGame(client) || !IsPlayerAlive(client)) return Plugin_Continue;


    int primary                = pack.ReadCell();
    int primary_ammo_type    = pack.ReadCell();
    int primary_ammo        = pack.ReadCell();
    int primary_clip        = pack.ReadCell();
    int secondary            = pack.ReadCell();
    int secondary_ammo_type    = pack.ReadCell();
    int secondary_ammo        = pack.ReadCell();
    int secondary_clip        = pack.ReadCell();

    if(primary != -1)
    {
        SetEntProp(client, Prop_Send, "m_iAmmo", primary_ammo, _, primary_ammo_type);
        SetEntProp(primary, Prop_Send, "m_iClip1", primary_clip);
    }

    if(secondary != -1)
    {
        SetEntProp(client, Prop_Send, "m_iAmmo", secondary_ammo, _, secondary_ammo_type);
        SetEntProp(secondary, Prop_Send, "m_iClip1", secondary_clip);
    }
    
    return Plugin_Continue;
}

Re: Weird bug in Counter-Strike: Source – Night vision gives ammo

Thanks so much!

I was also writing a SourceMod patch yesterday, which looks almost the same (but using the old syntax). Your solution hooking item_pickup may be more reliable though, but you would want to use EntIndexToEntRef() for the entity IDs I think just to be safe:

PHP Code:


		
			
public Action:CS_OnBuyCommand(clientID, const String:weapon[]) {

    

    if (IsValidClient(clientID) && IsPlayerAlive(clientID) && !IsFakeClient(clientID)) {

        

        if (StrEqual(weapon, "vest") || StrEqual(weapon, "vesthelm") || StrEqual(weapon, "nvgs")) {

            

            /**

            *    Find out current ammo and clip size of player

            */

            new PrimaryAmmo = -1;

            new PrimaryClipSize = -1;

            new SecondaryAmmo = -1;

            new SecondaryClipSize = -1;

            

            new PrimaryWeaponEntity = GetPlayerWeaponSlot(clientID, 0);

            new PrimaryWeaponEntityRef = -1;

            

            new SecondaryWeaponEntity = GetPlayerWeaponSlot(clientID, 1);

            new SecondaryWeaponEntityRef = -1;

            

            if (PrimaryWeaponEntity > -1) {

                PrimaryWeaponEntityRef = EntIndexToEntRef(PrimaryWeaponEntity);

                PrimaryAmmo = GetAmmo(clientID, 0);

                PrimaryClipSize = GetClipSize(PrimaryWeaponEntity);

            }

            

            if (SecondaryWeaponEntity > -1) {

                SecondaryWeaponEntityRef = EntIndexToEntRef(SecondaryWeaponEntity);

                SecondaryAmmo = GetAmmo(clientID, 1);

                SecondaryClipSize = GetClipSize(SecondaryWeaponEntity);

            }

            

            /**

            *    Cache information

            */

            new Handle:handle = CreateDataPack();

            

            WritePackCell(handle, GetClientUserId(clientID));

            WritePackCell(handle, PrimaryWeaponEntityRef);

            WritePackCell(handle, PrimaryAmmo);

            WritePackCell(handle, PrimaryClipSize);

            WritePackCell(handle, SecondaryWeaponEntityRef);

            WritePackCell(handle, SecondaryAmmo);

            WritePackCell(handle, SecondaryClipSize);



            /**

            *    Restore in the next frame, otherwise this will have no effect

            */

            RequestFrame(GameBugFix_RestoreClientAmmoAndClipSize, handle);

            

        }

        

    }

    

}



public GameBugFix_RestoreClientAmmoAndClipSize(Handle:handle) {

    

    ResetPack(handle);

    

    new clientID = GetClientOfUserId(ReadPackCell(handle));    

    new PrimaryWeaponEntity = ReadPackCell(handle);

    new PrimaryAmmo = ReadPackCell(handle);

    new PrimaryClipSize = ReadPackCell(handle);

    new SecondaryWeaponEntity = ReadPackCell(handle);

    new SecondaryAmmo = ReadPackCell(handle);

    new SecondaryClipSize = ReadPackCell(handle);



    if (IsValidClient(clientID) && IsPlayerAlive(clientID)) {

        

        /**

        *    Primary

        */

        if (PrimaryWeaponEntity != -1) {

            PrimaryWeaponEntity = EntRefToEntIndex(PrimaryWeaponEntity);

            

            if (IsValidEntity(PrimaryWeaponEntity)) {

                SetPlayerAmmoForWeaponEntity(clientID, PrimaryWeaponEntity, PrimaryAmmo);

                SetClipSize(PrimaryWeaponEntity, PrimaryClipSize);

            }

        }

    

        /**

        *    Secondary

        */    

        if (SecondaryWeaponEntity != -1) {

            SecondaryWeaponEntity = EntRefToEntIndex(SecondaryWeaponEntity);

    

            if (IsValidEntity(SecondaryWeaponEntity)) {

                SetPlayerAmmoForWeaponEntity(clientID, SecondaryWeaponEntity, SecondaryAmmo);

                SetClipSize(SecondaryWeaponEntity, SecondaryClipSize);

            }

        }

        

    }

    

    CloseHandle(handle);

    

}



stock bool:IsValidClient(const clientID) {



    if (!IsValidClientID(clientID)) {

        return false;

    }

    

    if (!IsClientInGame(clientID)) {

        return false;

    }



    return true;

    

}



stock GetAmmo(const clientID, const slot) {

    new weapon = GetPlayerWeaponSlot(clientID, slot);

    

    if (IsValidEntity(weapon)) {

        new offset = GetEntProp(weapon, Prop_Send, "m_iPrimaryAmmoType", 1) * 4;

        return GetEntData(clientID, Offset_m_iAmmo + offset);

    }

    

    return -1;

}



stock SetPlayerAmmoForWeaponEntity(const clientID, const entity, const amount) {

    new offset = GetEntProp(entity, Prop_Send, "m_iPrimaryAmmoType", 1) * 4;

    

    SetEntData(clientID, Offset_m_iAmmo + offset, amount, 4, true);

}



stock GetClipSize(const entity) {

    return GetEntProp(entity, Prop_Send, "m_iClip1");

}



stock SetClipSize(const entity, const amount) {

    SetEntProp(entity, Prop_Send, "m_iClip1", amount);

}

Re: Weird bug in Counter-Strike: Source – Night vision gives ammo

yes, entity ref ID is safer because of my delayed timer.