[Bacardi]

Rant:

This have nothing to do servers...

Response File

vpk a <vpkfile> @<filename>

Add files listed in a response file.
Response file filename.txt construct

This\source\address\to\file\is\the\same\destination\address into\VPK\filename.vtf
This\source\address\to\file\is\the\same\destination\address into\VPK\filename.vtf
This\source\address\to\file\is\the\same\destination\address into\VPK\filename.vtf
...

...game/custom/vpk_tool_@response_file.bat

Drag & drop "mod" folder onto batch file:
It collects certain files from certain folders inside "mod" and adds them in response file @<modfoldername>.txt
materials=*.vmt;*.vtf
models=*.mdl;*.phy;*.ani;*.vtx;*.vvd
sound=*.wav;*.mp3
particles=*.pcf;*.txt
scripts=*.res;*.txt
classes=*.res
shaders=*.vcs
- If batch file locate in right place (custom folder) and it find vpk.exe tool, it start create VPK by response file.
VPK files are created actually inside "mod" folder and batch file copy all vpk files from there to custom folder.
This add and update files inside previous VPK build, not remove files from VPK.
If you want remove some files from previous VPK, go delete manually VPK files inside "mod" folder.

- If you have both "key" files inside custom folder with base name "my", batch start sign your VPK

- If previous response file found, it rename that file before new one with timestamp [email protected] (you can delete those old files)
Code:

PHP Code:

@echo off

::                RESPONSE FILE @<mod folder>.txt
SET RESPONSEFILE="@%~n1.txt"

set timestamp=%date:~9%%date:~3,-4%-%time::=%
set timestamp=%timestamp:/=%
set timestamp=%timestamp:.=%
set timestamp=%timestamp:~,-3%

IF EXIST %RESPONSEFILE% move %RESPONSEFILE% "%timestamp%%RESPONSEFILE:"=%" >NUL
del %RESPONSEFILE% 2>NUL





::            LOOP
setlocal ENABLEDELAYEDEXPANSION
:: MATERIALS
set folder=materials
set file_extensions=*.vmt;*.vtf
echo.
echo.
echo.        Creating Response File %RESPONSEFILE%...
echo.
echo Please wait
:loop
<nul set /p =%folder%
FOR /R "%~n1\%folder%" %%i IN (%file_extensions%) do (
    set /a N+=1
    set "str=%%i"
    set "str=!str:*%~n1\=%~n1\!"

    echo !str:*%~n1\=!>>%RESPONSEFILE%

    IF !N!==100    (
        set N=0
        <nul set /p =.
    )
)
echo.
:: MODELS
IF %folder%==materials (
    set folder=models
    set file_extensions=*.mdl;*.phy;*.ani;*.vtx;*.vvd
    goto loop
)
:: SOUND
IF %folder%==models (
    set folder=sound
    set file_extensions=*.wav;*.mp3
    goto loop
)
:: PARTICLES
IF %folder%==sound (
    set folder=particles
    set file_extensions=*.pcf;*.txt
    goto loop
)
:: SCRIPTS
IF %folder%==particles (
    set folder=scripts
    set file_extensions=*.res;*.txt
    goto loop
)
:: RESOURCE
IF %folder%==scripts (
    set folder=resource
    set file_extensions=*.res;*.txt
    goto loop
)
:: CLASSES
IF %folder%==resource (
    set folder=classes
    set file_extensions=*.res
    goto loop
)
:: SHADERS
IF %folder%==classes (
    set folder=shaders
    set file_extensions=*.vcs
    goto loop
)
endlocal
echo.        Response File %RESPONSEFILE% ready !!
echo.



::            VPK TOOL
set VPK_EXE=..\..\
pushd .
CD %VPK_EXE%
SET VPK_EXE=%CD%\bin\vpk.exe
popd

IF EXIST "%VPK_EXE%" GOTO :vpk_step

echo.
echo ERROR!        ERROR!        ERROR!        ERROR!
echo.
SET BATCH=%~dp0
echo - Batch file is now located here
echo ...%BATCH:*common\=%
echo - The expected location of the vpk.exe
echo ...%VPK_EXE:*common\=%
echo.
echo.
echo Not such a file found
echo Exit the program...
echo.
echo ERROR!        ERROR!        ERROR!        ERROR!
pause
goto eof

:vpk_step
echo.
echo ] Found VPK tool : ...%VPK_EXE:*common\=%
echo ] VPK tool in action!!!

pushd .
cd %~n1
:: Sign your files if both key files exists
IF NOT EXIST "..\my.privatekey.vdf"    GOTO :skip_sign
IF NOT EXIST "..\my.publickey.vdf"    GOTO :skip_sign
echo Sign VPK...
"%VPK_EXE%" -M -K ..\my.privatekey.vdf -k ..\my.publickey.vdf a "%~n1" @"..\%RESPONSEFILE:"=%"
GOTO :skip_regular

:skip_sign
"%VPK_EXE%" a "%~n1" @"..\%RESPONSEFILE:"=%"

:skip_regular
copy "*.vpk" "..\" >NUL

popd

echo.
echo.    ALL DONE
pause 


Keyvalues Control File

vpk k <vpkfile> <keyvalues_filename>

Add files listed in a keyvalues control file.
keyvalues control file keyvalues_filename.txt construct

"source\address\to\file.vtf"
{
	"destpath"	"destination\address into\VPK\filename.vtf"
}
"source\address\to\file.vtf"
{
	"destpath"	"destination\address into\VPK\filename.vtf"
}
"source\address\to\file.vtf"
{
	"destpath"	"destination\address into\VPK\filename.vtf"
}
...

...game/custom/vpk_tool_keyvalues_file.bat

Drag & drop "mod" folder onto batch file:
It collects certain files from certain folders inside "mod" and adds them in keyvalues control file <modfoldername>.kv.txt
materials=*.vmt;*.vtf
models=*.mdl;*.phy;*.ani;*.vtx;*.vvd
sound=*.wav;*.mp3
particles=*.pcf;*.txt
scripts=*.res;*.txt
classes=*.res
shaders=*.vcs
- If batch file locate in right place (custom folder) and it find vpk.exe tool, it start create VPK by KV file.
This add and update files inside previous VPK build, not remove files from VPK.
If you want remove some files from previous VPK, delete manually VPK files.

- If you have both "key" files inside custom folder with base name "my", batch start sign your VPK

- If previous KV file found, it rename that file before new one with timestamp 20133004-135658mod.kv.txt (you can delete those old files)
Code:

PHP Code:

@echo off

::                KEYVALUES FILE <mod folder>.kv.txt
SET KVFILE="%~n1.kv.txt"

set timestamp=%date:~9%%date:~3,-4%-%time::=%
set timestamp=%timestamp:/=%
set timestamp=%timestamp:.=%
set timestamp=%timestamp:~,-3%

IF EXIST %KVFILE% move %KVFILE% "%timestamp%_%KVFILE:"=%" >NUL
del %KVFILE% 2>NUL



echo.//>>%KVFILE%
echo.//        Keyvalues Control File = %KVFILE%>>%KVFILE%
echo.//        made = %date%-%time%>>%KVFILE%
echo.//>>%KVFILE%
echo.>>%KVFILE%


::            LOOP
setlocal ENABLEDELAYEDEXPANSION
:: MATERIALS
set folder=materials
set file_extensions=*.vmt;*.vtf
echo.
echo.
echo.        Creating Keyvalues File %KVFILE%...
echo.
echo Please wait
:loop
<nul set /p =%folder%
FOR /R "%~n1\%folder%" %%i IN (%file_extensions%) do (
    set /a N+=1
    set "str=%%i"
    set "str=!str:*%~n1\=%~n1\!"

    echo "!str!">>%KVFILE%
    echo {>>%KVFILE%

    echo.    "destpath"    "!str:*%~n1\=!">>%KVFILE%

    echo }>>%KVFILE%

    IF !N!==100    (
        set N=0
        <nul set /p =.
    )
)
echo.

:: MODELS
IF %folder%==materials (
    set folder=models
    set file_extensions=*.mdl;*.phy;*.ani;*.vtx;*.vvd
    goto loop
)
:: SOUND
IF %folder%==models (
    set folder=sound
    set file_extensions=*.wav;*.mp3
    goto loop
)
:: PARTICLES
IF %folder%==sound (
    set folder=particles
    set file_extensions=*.pcf;*.txt
    goto loop
)
:: SCRIPTS
IF %folder%==particles (
    set folder=scripts
    set file_extensions=*.res;*.txt
    goto loop
)
:: RESOURCE
IF %folder%==scripts (
    set folder=resource
    set file_extensions=*.res;*.txt
    goto loop
)
:: CLASSES
IF %folder%==resource (
    set folder=classes
    set file_extensions=*.res
    goto loop
)
:: SHADERS
IF %folder%==classes (
    set folder=shaders
    set file_extensions=*.vcs
    goto loop
)
endlocal
echo.        Keyvalues File %KVFILE% ready !!
echo.



::            VPK TOOL
set VPK_EXE=..\..\
pushd .
CD %VPK_EXE%
SET VPK_EXE=%CD%\bin\vpk.exe
popd

IF EXIST "%VPK_EXE%" GOTO :vpk_step

echo.
echo ERROR!        ERROR!        ERROR!        ERROR!
echo.
SET BATCH=%~dp0
echo - Batch file is now located here
echo ...%BATCH:*common\=%
echo - The expected location of the vpk.exe
echo ...%VPK_EXE:*common\=%
echo.
echo.
echo Not such a file found
echo Exit the program...
echo.
echo ERROR!        ERROR!        ERROR!        ERROR!
pause
goto eof

:vpk_step
echo.
echo ] Found VPK tool : ...%VPK_EXE:*common\=%
echo ] VPK tool in action!!!

:: Sign your files if both key files exists
IF NOT EXIST "my.privatekey.vdf"    GOTO :skip_sign
IF NOT EXIST "my.publickey.vdf"        GOTO :skip_sign
echo Sign VPK...
"%VPK_EXE%" -M -K my.privatekey.vdf -k my.publickey.vdf k "%~n1" %KVFILE%
GOTO :skip_regular

:skip_sign
"%VPK_EXE%" k "%~n1" %KVFILE%

:skip_regular

echo.
echo.    ALL DONE
pause 


-P Use SteamPipe-friendly incremental build algorithm.
You more likely not need ever use this method. This is for heavy users. (I think)

vpk -P k <vpkfile> <keyvalues_filename>

Use SteamPipe-friendly incremental build algorithm.
Use with 'k' command.
For optimal incremental build performance, the control file used
for the previous build should exist and be named the same as the
input control file, with '.bak' appended, and each file entry
should have an 'md5' value. The 'md5' field need not be the
actual MD5 of the file contents, it is just a unique identifier
that will be compared to determine if the file contents has changed
between builds.
This option implies -M
keyvalues control file keyvalues_filename.txt construct and previous VPK build keyvalues_filename.txt.bak

"source\address\to\file.vtf"
{
	"destpath"	"destination\address into\VPK\filename.vtf"
	"MD5"		"a92cfdee21825a4d70a6765a99767c36"
}
"source\address\to\file.vtf"
{
	"destpath"	"destination\address into\VPK\filename.vtf"
	"MD5"		"a92cfdee21825a4d70a6765a99767c36"
}
"source\address\to\file.vtf"
{
	"destpath"	"destination\address into\VPK\filename.vtf"
	"MD5"		"a92cfdee21825a4d70a6765a99767c36"
}
...

...game/custom/vpk_tool_-P_keyvalues_file.bat

Download program http://sourceforge.net/projects/swis...wissfileknife/
and rename it sfk.exe and place in custom folder to get files MD5 checksum.

This SteamPipe-friendly incremental method is more likely to heavy users who have BIG project and VPK file (100MB or over)!

Let's say your mod size is 130MB and we chop it to 10MB size VPK files pieces (-c 10), just for that
players not need download whole 130MB VPK everytime when it is updated.
When in your project have a tiny change in just one file, MD5 checksum helps update your VPK's if file size not differs.
Then vpk.exe update just one of those VPK's files where your change have made.
Players now need only download 10MB update instead 130MB

To upload/update players VPKs files is whole different story, I don't know how to do that. Ask from Valve/Steam.


Batch create KV file list files inside mod folder and create new VPK when previous not exist.
And rename kv file after packing to mod.kv.txt.bak file. <- Remember keep this file with same VPK file.
Next time you pack this same mod and you have previous build VPK file and BAK file.
It check and compare KV files and make updates if have to.
Batch throw old bak file inside OLDKVFILE folder with timestamp and rename new KV file to BAK which match now your current VPK file.

PHP Code:

@echo off
:: Do we have this program to get files MD5 checksum ??
::http://stahlworks.com/dev/index.php?tool=md5list
::http://sourceforge.net/projects/swissfileknife/files/1-swissfileknife/
set sfk=0
IF EXIST sfk.exe set sfk=1


::                KEYVALUES FILE <mod folder>.kv.txt
SET KVFILE="%~n1.kv.txt"

set timestamp=%date:~9%%date:~3,-4%-%time::=%
set timestamp=%timestamp:/=%
set timestamp=%timestamp:.=%
set timestamp=%timestamp:~,-3%


echo.//>>%KVFILE%
echo.//        Keyvalues Control File = %KVFILE%>>%KVFILE%
echo.//        made = %date%-%time%>>%KVFILE%
echo.//>>%KVFILE%
echo.>>%KVFILE%


::            LOOP
setlocal ENABLEDELAYEDEXPANSION
:: MATERIALS
set folder=materials
set file_extensions=*.vmt;*.vtf
echo.
echo.
echo.        Creating Keyvalues File %KVFILE%...
IF %sfk%==1 echo.        Also collected files MD5 checksum...
echo.
echo Please wait
:loop
<nul set /p =%folder%
FOR /R "%~n1\%folder%" %%i IN (%file_extensions%) do (
    set /a N+=1
    set "str=%%i"
    set "str=!str:*%~n1\=%~n1\!"

    echo "!str!">>%KVFILE%
    echo {>>%KVFILE%

    echo.    "destpath"    "!str:*%~n1\=!">>%KVFILE%

    IF %sfk%==1 (
        FOR /F %%i in ('sfk.exe md5 "!str!"') DO set checksum=%%i
        echo.    "MD5"        "!checksum:~0,32!">>%KVFILE%
    )

    echo }>>%KVFILE%

    IF !N!==100    (
        set N=0
        <nul set /p =.
    )
)
echo.

:: MODELS
IF %folder%==materials (
    set folder=models
    set file_extensions=*.mdl;*.phy;*.ani;*.vtx;*.vvd
    goto loop
)
:: SOUND
IF %folder%==models (
    set folder=sound
    set file_extensions=*.wav;*.mp3
    goto loop
)
:: PARTICLES
IF %folder%==sound (
    set folder=particles
    set file_extensions=*.pcf;*.txt
    goto loop
)
:: SCRIPTS
IF %folder%==particles (
    set folder=scripts
    set file_extensions=*.res;*.txt
    goto loop
)
:: RESOURCE
IF %folder%==scripts (
    set folder=resource
    set file_extensions=*.res;*.txt
    goto loop
)
:: CLASSES
IF %folder%==resource (
    set folder=classes
    set file_extensions=*.res
    goto loop
)
:: SHADERS
IF %folder%==classes (
    set folder=shaders
    set file_extensions=*.vcs
    goto loop
)
endlocal
echo.        Keyvalues File %KVFILE% ready !!
echo.



::            VPK TOOL
set VPK_EXE=..\..\
pushd .
CD %VPK_EXE%
SET VPK_EXE=%CD%\bin\vpk.exe
popd

IF EXIST "%VPK_EXE%" GOTO :vpk_step

echo.
echo ERROR!        ERROR!        ERROR!        ERROR!
echo.
SET BATCH=%~dp0
echo - Batch file is now located here
echo ...%BATCH:*common\=%
echo - The expected location of the vpk.exe
echo ...%VPK_EXE:*common\=%
echo.
echo.
echo Not such a file found
echo Exit the program...
echo.
echo ERROR!        ERROR!        ERROR!        ERROR!
pause
goto eof

:vpk_step
echo.
echo ] Found VPK tool : ...%VPK_EXE:*common\=%
echo ] VPK tool in action!!!

:: Sign your files if both key files exists
IF NOT EXIST "my.privatekey.vdf"    GOTO :skip_sign
IF NOT EXIST "my.publickey.vdf"        GOTO :skip_sign
echo Sign VPK...
"%VPK_EXE%" -P -c 100 -K my.privatekey.vdf -k my.publickey.vdf k "%~n1" %KVFILE%
GOTO :skip_regular

:skip_sign
"%VPK_EXE%" -P -c 100 k "%~n1" %KVFILE%

:skip_regular

:: Found previous kv files ? Then rename and move them
IF EXIST "%KVFILE:"=%.bak" (
    IF NOT EXIST "oldkvfiles\." mkdir oldkvfiles
    move "%KVFILE:"=%.bak" "oldkvfiles\%timestamp%_%KVFILE:"=%.bak" >NUL
)
IF EXIST %KVFILE% move %KVFILE% "%KVFILE:"=%.bak" >NUL
del %KVFILE% 2>NUL


echo.
echo.    ALL DONE
pause 


[psychonic]

Very nice.

[Bacardi]

Some C++ developer could make a moar simple program to do these same things.
I start hate batch files ^^, annoying

[friagram]

would be nice if servers could allow clients to download and load vpks if they are signed and trusted by said server.
Guess this won't be supported since valve doesn't flush models/materials in memory once it's loaded, so if you go from one server to another, and something is in the same path, it won't know what to do with itself.