[MrPower]

Hellos

I would also like a radom player plugin, that is, for tero to choose a radom player and give 200 hp + 100 ap and for ct to give a radom player 250 hp + 150 ap, yes I would like a radom player (tero and ct) to appear after 60 sec.

[Napoleon_be]

Originally Posted by MrPower Hellos I would also like a radom player plugin, that is, for tero to choose a radom player and give 200 hp + 100 ap and for ct to give a radom player 250 hp + 150 ap, yes I would like a radom player (tero and ct) to appear after 60 sec.

How do you want this to happen? Every round? Using a command?

[v120kaaimcfg]

Originally Posted by MrPower Hellos I would also like a radom player plugin, that is, for tero to choose a radom player and give 200 hp + 100 ap and for ct to give a radom player 250 hp + 150 ap, yes I would like a radom player (tero and ct) to appear after 60 sec.

Here

PHP Code:

#include <amxmodx>
#include <cstrike>
#include <fun>

public plugin_init() 
{
    register_plugin("Random player bonus HP & AP", "1", "")
    register_event("HLTV", "event_new_round", "a", "1=0", "2=0")
}

public event_new_round()
{
    if(task_exists(987654))
    {
        remove_task(987654)
    }
    set_task(60.0, "random_bonus_HP_AP", 987654)
}

public random_bonus_HP_AP()
{
    new players_CT[32], numCT, players_T[32], numT
    get_players(players_CT, numCT, "aeh", "CT")
    get_players(players_T, numT, "aeh", "TERRORIST")

    if(numCT)
    {
        new randCT = players_CT[random(numCT)]
        set_user_health(randCT, get_user_health(randCT) + 250)
        cs_set_user_armor(randCT, get_user_armor(randCT) + 150, CS_ARMOR_VESTHELM)
        client_print(0, print_chat, "%n won 250HP + 150AP bonus!", randCT)
    }
    if(numT)
    {
        new randT = players_T[random(numT)]
        set_user_health(randT, get_user_health(randT) + 200)
        cs_set_user_armor(randT, get_user_armor(randT) + 100, CS_ARMOR_VESTHELM)
        client_print(0, print_chat, "%n won 200HP + 100AP bonus!", randT)
    }
} 


[MrPower]

I want each round to receive a radome ct or tero as I wrote above

[mlibre]

see

[Napoleon_be]

Untested as i have no server setup atm.

PHP Code:

#include <amxmodx>
#include <fun>
#include <cstrike>

#pragma semicolon 1

#define pluginName "RandomPlayerBenefits"
#define pluginVersion "1.0.0"
#define pluginAuthor "LadderGoat"

#if !defined MAX_PLAYERS
    #define MAX_PLAYERS 32
#endif

#define taskID 20874

public plugin_init()
{
    register_plugin(pluginName, pluginVersion, pluginAuthor);
    register_logevent("roundStart", 2, "1=Round_Start");
    register_logevent("roundEnd", 2, "1=Round_End");
}

public roundStart()
{
    if(task_exists(taskID))
        remove_task(taskID);

    set_task(60.0, "randomPlayerSelection" ,taskID);   
}

public roundEnd()
{
    if(task_exists(taskID))
        remove_task(taskID);
}

public randomPlayerSelection()
{
    new tPlayers[MAX_PLAYERS], tPlayerCount, ctPlayers[MAX_PLAYERS], ctPlayerCount;
    get_players(tPlayers, tPlayerCount, "ae", "TERRORIST");
    get_players(ctPlayers, ctPlayerCount, "ae", "CT");
    new teamSelector = random(1);
    
    if(teamSelector == 0 && tPlayerCount)
    {
        new randomTerrorist = tPlayers[random(tPlayerCount)];
        set_user_health(randomTerrorist, get_user_health(randomTerrorist) + 200);
        set_user_armor(randomTerrorist, get_user_armor(randomTerrorist) + 100);
    }

    else if(teamSelector == 1 && ctPlayerCount)
    {
        new randomCt = ctPlayers[random(ctPlayerCount)];
        set_user_health(randomCt, get_user_health(randomCt) + 250);
        set_user_armor(randomCt, get_user_armor(randomCt) + 150);
    }
} 


[MrPower]

It works, yes, I would like a message to appear on the tero and on the ct, that is, a message in the chat [AMXX] Player The name Random player received 200 hp and 100 ap. In the name where the name of the player is written, the name of the player should appear.

[Napoleon_be]

Here's an adjusted version. I also added some cvars so you can easily modify the prefix, health and armor values. Once again, untested.

PHP Code:

#include <amxmodx>
#include <fun>
#include <cstrike>

#pragma semicolon 1

#define pluginName "RandomPlayerBenefits"
#define pluginVersion "1.0.0"
#define pluginAuthor "LadderGoat"

#define taskID 20874

new messagePrefix;
new terroristHealth;
new terroristArmor;
new counterTerroristHealth;
new counterTerroristArmor;

public plugin_init()
{
    register_plugin(pluginName, pluginVersion, pluginAuthor);
    register_logevent("roundStart", 2, "1=Round_Start");
    register_logevent("roundEnd", 2, "1=Round_End");

    messagePrefix = register_cvar("rpb_prefix", "AMXx");

    terroristHealth = register_cvar("rpb_thealth", "200");
    terroristArmor = register_cvar("rpb_tarmor", "100");
    counterTerroristHealth = register_cvar("rpb_cthealth", "250");
    counterTerroristArmor = register_cvar("rpb_ctarmor", "150");
}

public roundStart()
{
    if(task_exists(taskID))
        remove_task(taskID);

    set_task(60.0, "randomPlayerSelection" ,taskID);   
}

public roundEnd()
{
    if(task_exists(taskID))
        remove_task(taskID);
}

public randomPlayerSelection()
{
    new tPlayers[MAX_PLAYERS], tPlayerCount, ctPlayers[MAX_PLAYERS], ctPlayerCount;
    new playerName[MAX_NAME_LENGTH];
    new teamSelector = random(1);
    new chatPrefix[9]; // 10 characters for a prefix should be more than enough. 
    
    get_players(tPlayers, tPlayerCount, "ae", "TERRORIST");
    get_players(ctPlayers, ctPlayerCount, "ae", "CT");
    get_pcvar_string(messagePrefix, chatPrefix, charsmax(chatPrefix));
    
    if(teamSelector == 0 && tPlayerCount)
    {
        new tHealth = get_pcvar_num(terroristHealth);
        new tArmor = get_pcvar_num(terroristArmor);
        new randomTerrorist = tPlayers[random(tPlayerCount)];

        set_user_health(randomTerrorist, get_user_health(randomTerrorist) + 200);
        set_user_armor(randomTerrorist, get_user_armor(randomTerrorist) + 100);
        get_user_name(randomTerrorist, playerName, charsmax(playerName));
        client_print_color(0, print_team_red, "^4[%s]^3 %s^1 was randomly picked and received an extra %i health and %i armor.", chatPrefix, playerName, tHealth, tArmor);
    }

    else if(teamSelector == 1 && ctPlayerCount)
    {
        new ctHealth = get_pcvar_num(counterTerroristHealth);
        new ctArmor = get_pcvar_num(counterTerroristArmor);
        new randomCt = ctPlayers[random(ctPlayerCount)];

        set_user_health(randomCt, get_user_health(randomCt) + ctHealth);
        set_user_armor(randomCt, get_user_armor(randomCt) + ctArmor);
        get_user_name(randomCt, playerName, charsmax(playerName));
        client_print_color(0, print_team_blue, "^4[%s]^3 %s^1 was randomly picked and received an extra %i health and %i armor.", chatPrefix, playerName, ctHealth, ctArmor);
    }
}