[altex]

I was trying to implement this ES code in sourcemod

        cmdFormat = 'es_xgive %s env_spark; ' % attacker
        cmdFormat += 'es_xfire %s env_spark SetParent !activator; ' % attacker
        cmdFormat += 'es_xfire %s env_spark AddOutput "spawnflags 896"; ' % attacker
        cmdFormat += 'es_xfire %s env_spark AddOutput "angles -90 0 0"; ' % attacker
        cmdFormat += 'es_xfire %s env_spark AddOutput "magnitude 8"; ' % attacker
        cmdFormat += 'es_xfire %s env_spark AddOutput "traillength 3"; ' % attacker
        cmdFormat += 'es_xfire %s env_spark StartSpark' % attacker
        es.server.queuecmd(cmdFormat)

That's how i was doing that

        new String:target[128];
        Format(target, sizeof(target), "target%i", client);
        DispatchKeyValue(client, "targetname", target);
        
        // And even so
        // new String:targetString[128];
        // Format(targetString, sizeof(targetString), "targetname %s", target);
        // SetVariantString(targetString);
        // AcceptEntityInput(client, "AddOutput");
                
        entSpark = CreateEntityByName("env_spark");
        DispatchKeyValue(entSpark, "spawnflags", "896");
        DispatchKeyValue(entSpark, "angles", "-90 0 0");
        DispatchKeyValue(entSpark, "magnitude", "8");
        DispatchKeyValue(entSpark, "traillength", "3");
        // And even so
        // DispatchKeyValue(entSpark, "parentname", target);
        DispatchSpawn(entSpark);
        
        SetVariantString(target);
        AcceptEntityInput(client, "SetParent");
        
        AcceptEntityInput(entSpark, "StartSpark");

        // And even so
        // AcceptEntityInput(entSpark, "StartSpark", client, client);

And it does not work

[Peoples Army]

In Source mod & AMxmodx you have to use a Temporary Entity to create those kind of effects, it's gotten allot easier since sorucemod, you used to have to write out 20 lines of code every time, now there are these nice functions to do ti for you.

http://wiki.alliedmods.net/TempEnts_...eMod_SDKTools)

[altex]

I was thinking about it. Thanks.
I think it will realy help.
But i've got one question, how to attack sparks effect to the player for making it moving with it?

[exvel]

Create repeatable timer with something like this:

PHP Code:

decl Float:fPos[3];
GetClientAbsOrigin(client, fPos);
TE_SetupSparks(fPos, dir, Magnitude, TrailLength);
TE_SendToAll(); 


[altex]

Originally Posted by exvel Create repeatable timer with something like this: PHP Code: decl Float:fPos[3]; GetClientAbsOrigin(client, fPos); TE_SetupSparks(fPos, dir, Magnitude, TrailLength); TE_SendToAll();

Yes, i was thinking about it, but it's not optimal solution.
I realy do not want to create many entities, if i just can create one.

[exvel]

Those are temp entities. There are very fast and not harmful for server cpu.

[altex]

Originally Posted by exvel Those are temp entities. There are very fast and not harmful for server cpu.

I understand you completely Thanks again. But.
A realy, realy do not want to create entities, and i only want to move one entity with the player. Just like it implemented in eventscripts. And i do not understand why it is not possible in sourcemod ))

I just can not allow myself as a programmer to create many entities if i just need one )) I hope you understant my problem.

[Peoples Army]

Its a temporary entity, the entity will kill itself as soon as the message is done

[altex]

Originally Posted by Peoples Army Its a temporary entity, the entity will kill itself as soon as the message is done

what message?

i want to kill that entity by timer or provide time to live , i dont want entity to be killed in very short time.

For example, there is a player, and i want that for 10 seconds there will be sparks under his feet. So i want to create sparks entity once, than move it with player, that kill that entity after 10 seconds left. Engine provides functionality to move that entity with player automaticaly, and to spark all that time, not just once. So that is what i'm going to implement.

[altex]

I DID IT ! WOW!

#include <sourcemod>
#include <sdktools>

#pragma semicolon 1

public Plugin:myinfo =
{
    name = "Test2",
    author = "Otstrel.ru Team",
    description = "Test2",
    version = "1",
    url = "http://otstrel.ru"
};

new g_sparks[MAXPLAYERS+1] = {-1, ...};

public OnPluginStart()
{
    HookEvent("weapon_fire", _WeaponFire);
    HookEvent("player_death", _PD);
}

public _WeaponFire(Handle:event, const String:name[], bool:dontBroadcast)
{
    new client = GetClientOfUserId(GetEventInt(event, "userid"));
    
    if ( start(client) )
    {
        CreateTimer(10.0, Timer_Spark, client);
    }
}

public _PD(Handle:event, const String:name[], bool:dontBroadcast)
{
    new client = GetClientOfUserId(GetEventInt(event, "userid"));
    stop(client);
}

start(client)
{
    if ( g_sparks[client]  > -1 )
    {
        return 0;
    }
    
    decl Float:fPos[3];
    GetClientAbsOrigin(client, fPos);
    
    new String:target[128];
    Format(target, sizeof(target), "target%i", client);
    DispatchKeyValue(client, "targetname", target);
        
    new entSpark = CreateEntityByName("env_spark");
    DispatchKeyValue(entSpark, "spawnflags", "896");
    DispatchKeyValue(entSpark, "angles", "-90 0 0");
    DispatchKeyValue(entSpark, "magnitude", "8");
    DispatchKeyValue(entSpark, "traillength", "3");
    DispatchSpawn(entSpark);
            
    SetEntPropVector(entSpark, Prop_Send, "m_vecOrigin", fPos);

    SetVariantString(target);
    AcceptEntityInput(entSpark, "SetParent");
        
    AcceptEntityInput(entSpark, "StartSpark");
    g_sparks[client] = entSpark;
    
    return 1;
}

stop(client)
{
    if ( g_sparks[client] < 0 )
    {
        return;
    }
    AcceptEntityInput(g_sparks[client], "StopSpark");
    AcceptEntityInput(g_sparks[client], "Kill");
    g_sparks[client] = -1;
}


public Action:Timer_Spark(Handle:timer, any:client)
{
    stop(client);
}

But i dont think this effect is a good enough for me )) I need something more expressive...
especialy in the first 10 second this effect looks like small light (( almost without sparks.