[satelitegames]

Hello I come here to ask for a help and I think that simple thing, so I would like to know how to ChatColor appear to all players on the server, after you have changed the player's Glow.

PHP Code:

ChatColor(id, "%s O Guarda ^4%s ^1mudou a cor do Prisioneiro ^4%s^1.", PREFIX_BRGAMES_1, szName, szName2) 


below code

PHP Code:

#include <amxmodx> 
#include <cstrike>
#include <hamsandwich>
#include <fun>
#include <satelite>

#define PREFIX_BRGAMES_1 "^4(^3( ^4BRGaMes^3!^4CS ^3)^4) ^1"

public plugin_init() 
{ 
    register_plugin("[BRGaMes!CS] Glow Menu", "1.0", "Satelite") 
    register_clcmd("amx_glow","glow_menu"); 
    
    RegisterHam(Ham_Spawn, "player", "fw_PlayerSpawn_Post", 1)

    register_logevent( "RoundStart", 2, "1=Round_Start" );
    register_logevent( "RoundEnd", 2, "1=Round_End" );
} 

public fw_PlayerSpawn_Post(id) 
{ 
    set_user_rendering(id)    
}

public RoundStart(id)
{
     if( is_user_alive( id ) )
     {
          set_user_rendering(id, kRenderFxNone, 0, 0, 0, kRenderNormal, 0 );
     }
}

public RoundEnd(id)
{    
     if( is_user_alive( id ) )
     {
          set_user_rendering(id, kRenderFxNone, 0, 0, 0, kRenderNormal, 0 );
     }
}

public glow_menu(id) 
{ 
    if (cs_get_user_team(id) != CS_TEAM_CT || !is_user_alive(id)) 
    {  
        return PLUGIN_HANDLED; 
    } 
    new menu = menu_create("[BRGaMes!CS] Glow Menu:", "glow_menu_handler"); 
    
    new players[32], pnum, tempid; 
    new szName[32], szTempid[10]; 
    
    get_players(players, pnum, "a"); 
    
    for( new i; i<pnum; i++ ) 
    { 
        tempid = players[i]; 
        
        if (cs_get_user_team(tempid) != CS_TEAM_T) 
        { 
            continue; 
        } 
        
        get_user_name(tempid, szName, 31); 
        num_to_str(tempid, szTempid, 9); 
        menu_additem(menu, szName, szTempid, 0); 
    } 
    
    menu_display(id, menu); 
    return PLUGIN_HANDLED; 
} 

public glow_menu_handler(id, menu, item) 
{ 
     if( item == MENU_EXIT ) 
     { 
          menu_destroy(menu); 
          return PLUGIN_HANDLED; 
     } 
    
     new data[6], iName[64]; 
     new access, callback; 
     menu_item_getinfo(menu, item, access, data,5, iName, 63, callback); 
    
     new tempid = str_to_num(data); 
     new szName[32], szName2[32]; 
     get_user_name(id, szName, 31); 
     get_user_name(tempid, szName2, 31);

     new iRandomNum
     iRandomNum = random_num( 1, 6 )
     switch( iRandomNum )
     {
          case 1: set_user_rendering(tempid, kRenderFxGlowShell, 255, 0, 0, kRenderNormal, 10)  // Vermelho
          case 2: set_user_rendering(tempid, kRenderFxGlowShell, 0, 255, 0, kRenderNormal, 10 ) // Verde
          case 3: set_user_rendering(tempid, kRenderFxGlowShell, 0, 0, 255, kRenderNormal, 10 ) // Azul
          case 4: set_user_rendering(tempid, kRenderFxGlowShell, 255, 0, 228, kRenderNormal, 10 ) // Rosa
          case 5: set_user_rendering(tempid, kRenderFxGlowShell, 192, 0, 255, kRenderNormal, 10 ) // Roxo
          case 6: set_user_rendering(tempid, kRenderFxGlowShell, 255, 255, 0, kRenderNormal, 10 ) // Amarelo
     }

     ChatColor(id, "%s O Guarda ^4%s ^1mudou a cor do Prisioneiro ^4%s^1.", PREFIX_BRGAMES_1, szName, szName2)
    
     menu_destroy(menu); 
     return PLUGIN_HANDLED; 
}

// ChatColor!
stock ChatColor(const id, const input[], any:...)
{
    new count = 1, players[32]
    static msg[191]
    vformat(msg, 190, input, 3)
    
    replace_all(msg, 190, "!g", "^4") // Verde
    replace_all(msg, 190, "!y", "^1") // Cor Padrão do CS
    replace_all(msg, 190, "!team", "^3") // Cor do Time
    replace_all(msg, 190, "!team2", "^0") // Cor do Time 2
    
    if (id) players[0] = id; else get_players(players, count, "ch")
    {
        for (new i = 0; i < count; i++)
        {
            if (is_user_connected(players[i]))
            {
                message_begin(MSG_ONE_UNRELIABLE, get_user_msgid("SayText"), _, players[i])
                write_byte(players[i]);
                write_string(msg);
                message_end();
            }
        }
    }
} 


The post is only showing up to the player that replaced the glow of the Prisoner

[wickedd]

PHP Code:

ChatColor(id, "%s O Guarda ^4%s ^1mudou a cor do Prisioneiro ^4%s^1.", PREFIX_BRGAMES_1, szName, szName2) 


PHP Code:

ChatColor(0, "%s O Guarda ^4%s ^1mudou a cor do Prisioneiro ^4%s^1.", PREFIX_BRGAMES_1, szName, szName2) 


[satelitegames]

wickedd hello, my problem and that this post appears for all players in the server.


example:

PHP Code:

if( is_user_alive( id ) ) 
{ 
      ChatColor(id, "%s O Guarda ^4%s ^1mudou a cor do Prisioneiro ^4%s^1.", PREFIX_BRGAMES_1, szName, szName2)
} 


For all players from the server to see the message in the chat

[Bilal Pro]

I think u mean,

PHP Code:

ColorChat(id, COLOR, "%s O Guarda ^4%s ^1mudou a cor do Prisioneiro ^4%s^1.", PREFIX_BRGAMES_1, szName, szName2) 


[wickedd]

If you want everyone to see it,change "id" to "0".

ChatColor(0, "%s O Guarda ^4%s ^1mudou a cor do Prisioneiro ^4%s^1.", PREFIX_BRGAMES_1, szName, szName2)

[satelitegames]

Hello Thanks a lot!, That was it