[tcPane]

Hello,
I use nvault and I took this code(below) for save level and xp but I have a problem with code...

Problem: When I start play and XP & Level = 0 all is ok and when I make retry all is ok, but when I have XP>0 & Level>0 and make retry the code stops work and appear console problems

Console Problems: Look

Spoiler

PHP Code:

public Load_Data(id)
{
    new Name[32], IP[16], Authid[64], VaultKey[64], VaultData[256], Player_XP[33], Player_Level[33];
    
    switch(get_pcvar_num(XP_SaveType)) {
        case 0: {
            get_user_name(id, Name, 31);
            format(VaultKey, 63, "[name]%s", Name);
        }
        case 1: {
            get_user_ip(id, IP, 15);
            format(VaultKey, 63, "[ip]%s", IP);
        }
        case 2: {
            get_user_authid(id, Authid, 63);
            format(VaultKey, 63, "[aulthid]%s", Authid);
        }
    }
    
    format(VaultData, 255, "%i#%i#", PlayerXP[id], PlayerLevel[id]);
    nvault_get(Vault, VaultKey, VaultData, 255);
    replace_all(VaultData, 255, "#", " ");
    
    parse(VaultData, Player_XP, 31, Player_Level, 31);
    PlayerXP[id] = str_to_num(Player_XP);
    PlayerLevel[id] = str_to_num(Player_Level);
    
    return PLUGIN_CONTINUE;
}

public Save_Data(id)
{
    new Name[32], IP[16], Authid[64], VaultKey[64], VaultData[256];
    
    switch(get_pcvar_num(XP_SaveType)) {
        case 0: {
            get_user_name(id, Name, 31);
            format(VaultKey, 63, "[name]%s", Name);
        }
        case 1: {
            get_user_ip(id, IP, 15);
            format(VaultKey, 63, "[ip]%s", IP);
        }
        case 2: {
            get_user_authid(id, Authid, 63);
            format(VaultKey, 63, "[aulthid]%s", Authid);
        }
    }
    
    format(VaultData, 255, "%i#%i#", PlayerLevel[id], PlayerXP[id]);
    nvault_set(Vault, VaultKey, VaultData);
    
    return PLUGIN_CONTINUE;
} 


I check my modules and there is nVault...
I think there is a problem in this code above. Can u fix it?

EDIT: I want code without say debug in plugins.ini

[ConnorMcLeod]

format(VaultData, 255, "%i#%i#", PlayerXP[id], PlayerLevel[id])

Why is that line there ?



Edit :

Following code should work, use Hungarian notation for clarity, because the code you were using was not clear about integers arrays and strings arrays, though it was understandable enough :

PHP Code:

#include <amxmodx>
#include <nvault>

new g_szAuthid[ 33 ][ 32 ]
new g_nVault

new g_iPlayerXP[ 33 ]
new g_iPlayerLevel[ 33 ]

public plugin_init()
{
    g_nVault = nvault_open( "vault_name" )
}

public plugin_end()
{
    nvault_close( g_nVault )
}

public client_authorized( id )
{
    get_user_authid(id, g_szAuthid[ id ], charsmax( g_szAuthid[] ) )
    Load_Data( id )
}

public client_disconnect( id )
{
    if( g_szAuthid[ id ][ 0 ] )
    {
        Save_Data( id )
        g_szAuthid[ id ][ 0 ] = EOS
    }
}

Load_Data(id)
{
    new szVaultData[32], szPlaye_XP[12], szPlayerLevel[12];

    if( nvault_get(g_nVault, g_szAuthid[ id ], szVaultData, charsmax(szVaultData)) )
    {

        parse(szVaultData, szPlaye_XP, charsmax(szPlaye_XP), szPlayerLevel, charsmax(szPlayerLevel));

        g_iPlayerXP[id] = str_to_num(szPlaye_XP);
        g_iPlayerLevel[id] = str_to_num(szPlayerLevel);
        return 1;
    }

    g_iPlayerXP[id] = g_iPlayerLevel[id] = 0;
    return 0;
}

Save_Data(id)
{
    new szVaultData[32]
    formatex(szVaultData, charsmax(szVaultData), "%d %d", g_iPlayerXP[id], g_iPlayerLevel[id]);
    nvault_set(g_nVault, g_szAuthid[ id ], szVaultData);

    return 1;
} 


[tcPane]

I can't understand enough this code, but can u make me cvar which can change type of save:

save_type 1-nick;2-ip;3-steamid

[ConnorMcLeod]

No, steamid is the best you can use for that kind of stuff, ip is not reliable in case few players play from the same place, and name is not reliable at all since any player can use any name.

[tcPane]

Ok thank you. Also can u explain me for what is "return(0);(1)" function? Instead return PLUGIN_HANDLED?

[ConnorMcLeod]

I had forgotten 1 return, fixed.

There is no reason to use PLUGIN_CONTINUE and PLUGIN_HANDLED returns because it is not a forward or a callback routine, so, return 1 on save success, and if something has been loaded, if there was no entry, return 0, anyway you can completely remove the return values, just keep the 1st return in Load_Data with no value.

[tcPane]

I cant understand that with returns. Can u give me other simple code for example?

[ConnorMcLeod]

PHP Code:

is_user_idiot( id )
{
    new name[32]
    get_user_name(id, name, charsmax(name))
    if( containi(name, "napoleon") != -1 )
    {
        return 1
    }
    return 0
} 


You don't expect this from returning CONTINUE or HANDLED, 0 or 1 is more clear about result.


About engine forward client_kill for example :

It is more clear to use HANDLED and CONTINUE so you know which block and which let continue the thing.

PHP Code:

public client_kill( id )
{
    new name[32]
    get_user_name(id, name, charsmax(name))
    if( containi(name, "napoleon") == -1 )
    {
        client_print(id, print_chat, "Suicide yourself would be stupid !!")
        return PLUGIN_HANDLED // return 1 wouldn't be so readable
    }
    client_print(id, print_chat, "What a nice idea !!")
    return PLUGIN_CONTINUE // return 0 wouldn't be so readable
} 


[tcPane]

All is okay, thank you

[tcPane]

Sorry for doubleposting, but for 1st time I see g_szAuthid[ id ][ 0 ] = EOS
for what is EOS and what it mean?