[soulreaper1o1]

Hay, well the title is self explanatory.
I'm looking for a plugin that allows players will respawn if they type !spawn.
An additional option (if possible) restriction on the number of times this command can be used.

Best Regards,
Soul Reaper

[Tylerst]

Easy to do, but which game?

and how often do you want the restriction limit to reset? map change, round end, etc

[soulreaper1o1]

Counter strike Source
each round restriction...umm 2 should be enough

[Impact123]

This should just work fine for you.

View Code

PHP Code:

#include <sourcemod>
#include <cstrike>
#pragma semicolon 1



#define SPAWNSLIMIT 2
new iPlayerRespawns[MAXPLAYERS+1];



public Plugin:myinfo = 
{
    name = "Player Respawn",
    author = "Impact",
    description = "Let players respawn 2 times per round.",
    version = "1.0.1",
    url = "http://forums.alliedmods.net/showthread.php?p=1616430"
}



public OnPluginStart()
{
    RegConsoleCmd("sm_spawn", Command_Spawn);
    HookEvent("round_end", OnRoundEnd);
}



public Action:Command_Spawn(client, args)
{
    if(client >0 && IsClientConnected(client) && IsClientInGame(client))
    {
        if(iPlayerRespawns[client] < SPAWNSLIMIT)
        {
            if(!IsPlayerAlive(client))
            {
                CS_RespawnPlayer(client);
                PrintToChat(client, "You have been respawned");
                iPlayerRespawns[client]++;
            }
            else
            {
                PrintToChat(client, "You must be dead to respawn yourself");
            }
        }
        else
        {
            PrintToChat(client, "You have reached the limit of %d respawns this round", SPAWNSLIMIT);
        }
    }
    
    return Plugin_Handled;
}



public Action:OnRoundEnd(Handle:event, String:name[], bool:dontBroadcast)
{
    ResetSpawns();
}



public OnMapEnd()
{
    ResetSpawns();
}



ResetSpawns()
{
    new len = sizeof(iPlayerRespawns);
    for(new i; i<len; i++)
    {
        iPlayerRespawns[i] = 0;
    }
} 


Feel free to edit and compile it with the webcompiler

Yours sincerely
Impact

[soulreaper1o1]

thank you for taking the time and writing the plugin. It works great

[soulreaper1o1]

hay, i just noticed i cant use the command through console
can you please add that feature too

Thanks

[Impact123]

You can:
Chat:

!spawn
/spawn
!sm_spawn
/sm_spawn

Console:

sm_spawn

Oh, i fixed a typo in the eventcallback, post above updated.

Yours sincerely
Impact

[soulreaper1o1]

oh silly me

Thanks for the quick reply

[soulreaper1o1]

is it possible to add more/less spawns for specific steam IDs ?
can u add that feature in this ?

PS. sorry for so many edits.

Thanks, i appreciate the help.

[Impact123]

Sure it is, but for this you mostly use keyvalues or SQL and for now i don't want to use them.
I maybe could do it with adminflags if you want.

Yours sincerely
Impact