[Nikol4u]

I use this code so people in my server would switch between being CT or spectators. For a reason, sometimes it buggs and the guy who is CT goes to SPEC (on player status (TAB) it shows he's SPEC), but he is alive and he can play (basically he stays CT, just his team is SPEC).

Can you tell me what do I do wrong?

cmdSpectate() is triggered on say /spec and say /ct

public cmdSpectate( plr )
{
	set_hudmessage( 0, 150, 250, -1.0, -0.1, 0, 6.0, 1.9, 0.0, 0.0, 1 );
	
	if( cs_get_user_team( plr ) != CS_TEAM_SPECTATOR )
	{
		
		g_bTimerStarted[plr] = false;
		show_hudmessage( plr, "You have become a spectator" );
		
		set_pev( plr, pev_solid, SOLID_NOT );
		set_pev( plr, pev_movetype, MOVETYPE_FLY );
		set_pev( plr, pev_effects, EF_NODRAW );
		set_pev( plr, pev_deadflag, DEAD_DEAD );
		set_pev( plr, pev_takedamage, DAMAGE_NO );
		cs_set_user_team( plr, CS_TEAM_SPECTATOR );
		entity_set_int( plr, EV_INT_deadflag, DEAD_DISCARDBODY );
		set_entity_flags( plr, FL_FROZEN, 0 );
	}
	else
	{
		cs_set_user_team( plr, CS_TEAM_CT, CS_CT_URBAN );
		set_pev( plr, pev_effects, 0 );
		set_pev( plr, pev_movetype, MOVETYPE_WALK );
		set_pev( plr, pev_deadflag, DEAD_NO );
		set_pev( plr, pev_takedamage, DAMAGE_AIM );
		cs_user_spawn( plr );
		
		g_bDuck[plr] = true;
		
		if( !user_has_weapon( plr, CSW_KNIFE ) )
		{
			fm_give_item( plr, "weapon_knife" );
		}
						
		if( !user_has_weapon( plr, CSW_USP ) )
		{
			fm_give_item( plr, "weapon_usp" );
			cs_set_user_bpammo( plr, CSW_USP, 36 );
		}
		
		show_hudmessage( plr, "You have become a counter-terrorist" );
	}
	
	return PLUGIN_HANDLED;
}

[ConnorMcLeod]

I think i have something really better but i can't find it, so try this for the moment :

PHP Code:

/*    Formatright © 2009, ConnorMcLeod

    Kz ChooseTeam is free software;
    you can redistribute it and/or modify it under the terms of the
    GNU General Public License as published by the Free Software Foundation.

    This program is distributed in the hope that it will be useful,
    but WITHOUT ANY WARRANTY; without even the implied warranty of
    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
    GNU General Public License for more details.

    You should have received a copy of the GNU General Public License
    along with Kz ChooseTeam; if not, write to the
    Free Software Foundation, Inc., 59 Temple Place - Suite 330,
    Boston, MA 02111-1307, USA.
*/

#include <amxmodx>
#include <fakemeta>

#define VERSION "0.3.0"

#define m_fGameHUDInitialized 349

#define SetIdBits(%1,%2)        %1 |= 1<<(%2 & 31)
#define ClearIdBits(%1,%2)    %1 &= ~( 1<<(%2 & 31) )
#define GetIdBits(%1,%2)        %1 &  1<<(%2 & 31)

new g_bDontHook

#define CS_TEAM_CT 2
#define CS_TEAM_SPECTATOR 4
#define fm_cs_get_user_team(%1)    get_pdata_int(%1, 114)

#define OFFSET_CAN_CHOOSETEAM 125
const CANT_CHOOSETEAM = 1<<8
#define AllowPlayerChooseTeam(%1)    set_pdata_int(%1, OFFSET_CAN_CHOOSETEAM, get_pdata_int(%1, OFFSET_CAN_CHOOSETEAM) & ~CANT_CHOOSETEAM)

new gmsgTextMsg

public plugin_init()
{
    register_plugin("Kz ChooseTeam", VERSION, "ConnorMcLeod")

    register_clcmd("say /spec", "ClientCommand_Spec")
    register_clcmd("say /ct", "ClientCommand_CT")
    register_clcmd("chooseteam", "ClientCommand_ChooseTeam")

    register_menucmd(register_menuid("#Team_Select_Spect"), 51, "Menu_ChooseTeam")

    gmsgTextMsg = get_user_msgid("TextMsg")
}

public client_putinserver(id)
{
    SetIdBits(g_bDontHook, id)
}

public ClientCommand_ChooseTeam(id)
{
    ClearIdBits(g_bDontHook, id)
    AllowPlayerChooseTeam(id)
    show_menu(id, 51, "#Team_Select_Spect", -1)

    return PLUGIN_HANDLED
}

public Menu_ChooseTeam(id, iKey)
{
    if( GetIdBits(g_bDontHook, id) )
    {
        ClearIdBits(g_bDontHook, id)
        return PLUGIN_CONTINUE
    }

    switch(iKey)
    {
        case 1:
        {
            ClientCommand_CT(id)
        }
        case 5:
        {
            ClientCommand_Spec(id)
        }
    }
    return PLUGIN_HANDLED
}

public ClientCommand_Spec(id)
{
    if( fm_cs_get_user_team(id) != CS_TEAM_SPECTATOR )
    {
        SetIdBits(g_bDontHook, id)
        new BLOCK_RESTORE = get_msg_block(gmsgTextMsg)
        set_msg_block(gmsgTextMsg, BLOCK_ONCE)
        dllfunc(DLLFunc_ClientPutInServer, id)
        set_msg_block(gmsgTextMsg, BLOCK_RESTORE)
        set_pdata_int(id, m_fGameHUDInitialized, 1)
        engclient_cmd(id, "jointeam", "6")
        client_cmd(id, "slot1")
        return PLUGIN_CONTINUE
    }
    return PLUGIN_HANDLED
}

public ClientCommand_CT(id)
{
    if( fm_cs_get_user_team(id) != CS_TEAM_CT )
    {
        new iRestore = get_pdata_int(id, 510)
        new bVGUI = iRestore & (1<<0)
        if( bVGUI )
        {
            set_pdata_int(id, 510, iRestore & ~(1<<0))
        }
        AllowPlayerChooseTeam(id)
        new BLOCK_RESTORE = get_msg_block(gmsgTextMsg)
        set_msg_block(gmsgTextMsg, BLOCK_ONCE)
        engclient_cmd(id, "jointeam", "2")
        engclient_cmd(id, "joinclass", "1")
        set_msg_block(gmsgTextMsg, BLOCK_RESTORE)
        client_cmd(id, "slot1")
        if( bVGUI )
        {
            set_pdata_int(id, 510, iRestore)
        }
        return PLUGIN_CONTINUE
    }
    return PLUGIN_HANDLED
} 


EDIT : Try rather this :

PHP Code:

/*    Formatright © 2011, ConnorMcLeod

    This plugin is free software;
    you can redistribute it and/or modify it under the terms of the
    GNU General Public License as published by the Free Software Foundation.

    This program is distributed in the hope that it will be useful,
    but WITHOUT ANY WARRANTY; without even the implied warranty of
    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
    GNU General Public License for more details.

    You should have received a copy of the GNU General Public License
    along with this plugin; if not, write to the
    Free Software Foundation, Inc., 59 Temple Place - Suite 330,
    Boston, MA 02111-1307, USA.
*/

#include <amxmodx>
#include <fakemeta>

#define VERSION "0.0.1"
#define PLUGIN "Spec"

#define m_iDefaultItems         120
#define m_iJoinedState 121
#define m_iMenuId 205

const DEFAULTITEMS_GIVEN  =    (1<<0)
#define JOIN_ONTEAM             5

new gmsgShowMenu, gmsgVGUIMenu

public plugin_init()
{
    register_plugin(PLUGIN, VERSION, "ConnorMcLeod")

    gmsgShowMenu = get_user_msgid("ShowMenu")
    gmsgVGUIMenu = get_user_msgid("VGUIMenu")

    register_clcmd("say /spec", "ClCmd_Spec")
    register_clcmd("say /ct", "ClCmd_Ct")
}

public ClCmd_Spec( id )
{
    if( is_user_alive(id) )
    {
        user_kill(id, 1) // this is exactly what is done if you select spectator team during freezetime
    }
    engclient_cmd(id, "jointeam", "6")
}

public ClCmd_Ct( id )
{
    set_pev(id, pev_deadflag, DEAD_NO) // allow return CT the same round
    set_pdata_int(id, m_iMenuId, 0) // in case we are already in such a menu

    new iBlockShowMenu = get_msg_block(gmsgShowMenu)
    if( iBlockShowMenu != BLOCK_SET )
    {
        if( !iBlockShowMenu )
        {
            set_msg_block(gmsgShowMenu, BLOCK_ONCE)
        }
    }
    new iBlockVGUIMenu = get_msg_block(gmsgVGUIMenu)
    if( iBlockVGUIMenu != BLOCK_SET )
    {
        if( !iBlockVGUIMenu )
        {
            set_msg_block(gmsgVGUIMenu, BLOCK_ONCE)
        }
    }

    engclient_cmd(id, "jointeam", "2")

    if( !iBlockShowMenu )
    {
        set_msg_block(gmsgShowMenu, BLOCK_NOT)
    }
    if( !iBlockVGUIMenu )
    {
        set_msg_block(gmsgVGUIMenu, BLOCK_NOT)
    }

    engclient_cmd(id, "joinclass", "2")

    set_pdata_int(id, m_iDefaultItems, get_pdata_int(id, m_iDefaultItems) & ~DEFAULTITEMS_GIVEN)
    set_pdata_int(id, m_iJoinedState, JOIN_ONTEAM)
    set_pev(id, pev_deadflag, DEAD_RESPAWNABLE)
    dllfunc(DLLFunc_Think, id)
}

// Observator modes
// enum
// {
    // OBS_NONE = 0,
    // OBS_CHASE_LOCKED,
    // OBS_CHASE_FREE, 
    // OBS_ROAMING, // free look
    // OBS_IN_EYE, // first person view
    // OBS_MAP_FREE, 
    // OBS_MAP_CHASE, 
// } 


[Nikol4u]

Isn't there a way to do this without actually killing the guy?

[ConnorMcLeod]

Try setting deadflag, but you may need to strip his weapons first.

[Nikol4u]

Originally Posted by Nikol4u set_pev( plr, pev_deadflag, DEAD_DEAD );

Isn't that the deadflag?

The thing is it happens randomly, sometimes it works perfectly, some times spectators move around and bug people as the semiclip won't work for them

[Leon M.]

It sounds lhat you using it for Kreedz. I'm right?

[Nikol4u]

Originally Posted by Leon M. It sounds lhat you using it for Kreedz. I'm right?

Yeah I am running KZ server.

Every plugin I have seen which has /spec /ct uses the same function calls which are in my cmdSpectate() function as well, but for a reason it does not work properly.

I guess @ConnorMcLeod would work totally fine (I tested it on LAN it does work) but I prefer if the user doesn't get killed. If no other way, I will use his method though.

[Leon M.]

I'm using a private Kreedz plugin but I can help you anyways. Please consider it is working just fine for me but I removed some code from the function since it is interacting with other features of my mod. May there are similar features on your mod, I don't know.

Take it as an example.

Remarks I'm using this function as a toggle in my menu. To en- or diable it you just need to call the function cmd_spectator again.

PHP Code:

new bool:g_bSpectator[33]
new Float:g_f_vSpecAngles[33][3]
new Float:g_f_vSpecOrigin[33][3]

public cmd_spectator(id){

    if (g_bSpectator[id]){
        g_bSpectator[id] = false

        // Mark player as ct
        cs_set_user_team(id, CS_TEAM_CT)
        set_pev(id, pev_deadflag, DEAD_NO)
        set_pev(id, pev_movetype, MOVETYPE_WALK)
        set_pev(id, pev_solid, SOLID_SLIDEBOX)
        set_pev(id, pev_takedamage, DAMAGE_AIM)
        set_pev(id, pev_effects, pev(id, pev_effects) & ~EF_NODRAW)

        // Respawn player
        ExecuteHamB(Ham_CS_RoundRespawn, id)

        // Old position has been stored
        if (!(g_f_vSpecOrigin[id][0] == 0.0 && g_f_vSpecOrigin[id][1] == 0.0 && g_f_vSpecOrigin[id][2] == 0.0)){

            // Teleport player
            set_pev(id, pev_flags, pev(id, pev_flags) | FL_DUCKING)
            set_pev(id, pev_fuser2, 0.0)
            set_pev(id, pev_velocity, {0.0, 0.0, 0.0})
            engfunc(EngFunc_SetOrigin, id, g_f_vSpecOrigin[id])
            engfunc(EngFunc_SetSize, id, {-16.0, -16.0, -18.0}, {16.0, 16.0, 18.0})

            // Set old angles
            set_pev(id, pev_angles, g_f_vSpecAngles[id])
            set_pev(id, pev_fixangle, 1)
        }
    }
    else{
        if (!is_user_alive(id)){
            client_print(id, print_chat, "[AMXX] You must be alive to use this command.")
            return
        }
        if (!(pev(id, pev_flags) & FL_ONGROUND)){
            client_print(id, print_chat, "[AMXX] You can't join to the spectators. You must stand on a ground.")
            return
        }

        g_bSpectator[id] = true
        g_f_vSpecOrigin[id][0] = 0.0
        g_f_vSpecOrigin[id][1] = 0.0
        g_f_vSpecOrigin[id][2] = 0.0
        pev(id, pev_v_angle, g_f_vSpecAngles[id])
        pev(id, pev_origin, g_f_vSpecOrigin[id])

        // FL_FROZEN must be removed
        set_pev(id, pev_flags, pev(id, pev_flags) & ~FL_FROZEN)

        // Mark player as spectator
        cs_set_user_team(id, CS_TEAM_SPECTATOR)
        set_pev(id, pev_deadflag, DEAD_DEAD)
        set_pev(id, pev_movetype, MOVETYPE_FLY)
        set_pev(id, pev_solid, SOLID_NOT)
        set_pev(id, pev_takedamage, DAMAGE_NO)
        set_pev(id, pev_effects, pev(id, pev_effects) | EF_NODRAW)
    }
} 


EDIT: Looks pretty equal, at least with team switch

[ConnorMcLeod]

Try this (kill shouldn't be noticable) :

PHP Code:

/*    Formatright © 2011, ConnorMcLeod

    This plugin is free software;
    you can redistribute it and/or modify it under the terms of the
    GNU General Public License as published by the Free Software Foundation.

    This program is distributed in the hope that it will be useful,
    but WITHOUT ANY WARRANTY; without even the implied warranty of
    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
    GNU General Public License for more details.

    You should have received a copy of the GNU General Public License
    along with this plugin; if not, write to the
    Free Software Foundation, Inc., 59 Temple Place - Suite 330,
    Boston, MA 02111-1307, USA.
*/

#include <amxmodx>
#include <fakemeta>

#tryinclude <cstrike_pdatas>

#if !defined _cbaseentity_included
        #assert Cstrike Pdatas and Offsets library required! Read the below instructions:   \
                1. Download it at forums.alliedmods.net/showpost.php?p=1712101#post1712101   \
                2. Put it into amxmodx/scripting/include/ folder   \
                3. Compile this plugin locally, details: wiki.amxmodx.org/index.php/Compiling_Plugins_%28AMX_Mod_X%29   \
                4. Install compiled plugin, details: wiki.amxmodx.org/index.php/Configuring_AMX_Mod_X#Installing
#endif

#define VERSION "0.0.1"
#define PLUGIN "Spec"

new gmsgShowMenu, gmsgVGUIMenu

public plugin_init()
{
    register_plugin(PLUGIN, VERSION, "ConnorMcLeod")

    gmsgShowMenu = get_user_msgid("ShowMenu")
    gmsgVGUIMenu = get_user_msgid("VGUIMenu")

    register_clcmd("say /spec", "ClCmd_Spec")
    register_clcmd("say /ct", "ClCmd_Ct")
}

public ClCmd_Spec( id )
{
    if( is_user_alive(id) )
    {
        set_pdata_bool(id, m_bBlastDamaged, true)
        user_kill(id, 1) // this is exactly what is done if you select spectator team during freezetime
    }
    engclient_cmd(id, "jointeam", "6")
}

public ClCmd_Ct( id )
{
    set_pev(id, pev_deadflag, DEAD_NO) // allow return CT the same round
    set_pdata_int(id, m_iMenu, 0) // in case we are already in such a menu

    new iBlockShowMenu = get_msg_block(gmsgShowMenu)
    if( iBlockShowMenu != BLOCK_SET )
    {
        if( !iBlockShowMenu )
        {
            set_msg_block(gmsgShowMenu, BLOCK_ONCE)
        }
    }
    new iBlockVGUIMenu = get_msg_block(gmsgVGUIMenu)
    if( iBlockVGUIMenu != BLOCK_SET )
    {
        if( !iBlockVGUIMenu )
        {
            set_msg_block(gmsgVGUIMenu, BLOCK_ONCE)
        }
    }

    engclient_cmd(id, "jointeam", "2")

    if( !iBlockShowMenu )
    {
        set_msg_block(gmsgShowMenu, BLOCK_NOT)
    }
    if( !iBlockVGUIMenu )
    {
        set_msg_block(gmsgVGUIMenu, BLOCK_NOT)
    }

    engclient_cmd(id, "joinclass", "2")

    set_pdata_bool(id, m_bHasReceivedDefItems, false)
    set_pdata_int(id, m_iJoinedState, 5)
    set_pev(id, pev_deadflag, DEAD_RESPAWNABLE)
    dllfunc(DLLFunc_Think, id)
} 


[Nikol4u]

I used Leon's code as it was easier for me to use it and implemented but it was still buggable.

This is a demo of the bug: http://www.sendspace.com/file/081rgd
This is the map (Nukk_miniegypt) http://www.sendspace.com/file/q16hfr

It is possible that to happen from something else? The only thing that has interaction in some why is the semiclip. I use skyjur's one from this post http://forums.alliedmods.net/showthr...358#post699358