[administratora]

Can someone share that plugin? When somebody stab you or slash you, you get a message in chat Player killed you from 1.58m. and he gets a message You killed Player1 from 1.58m. There is a plugin similar to that one but it shows the kill in units and in a hud

[edon1337]

Test

#include < amxmodx >
#include < fakemeta >
#include < hamsandwich >

public plugin_init( ) {

    register_plugin( "Knife Kill Distance", "1.0", "DoNii" ) ;

    RegisterHam( Ham_Killed, "player", "fw_HamKilledPost", 1 ) ;
}

public fw_HamKilledPost( victim, attacker, shouldgib ) {

    if( ! is_user_connected( attacker ) || ! is_user_connected( victim ) )
    return HAM_IGNORED ;

    if( get_user_weapon( attacker ) != CSW_KNIFE )
    return HAM_IGNORED ;

    new szName[ 32 ], Float:fVictimOrigin[ 3 ], Float:fAttackerOrigin[ 3 ], Float:fDistance ;
    get_user_name( attacker, szName, charsmax( szName ) ) ;

    pev( victim, pev_origin, fVictimOrigin ) ;
    pev( attacker, pev_origin, fAttackerOrigin ) ;
    
    fDistance = get_distance_f( fAttackerOrigin, fVictimOrigin ) ;
    fDistance *= 0.0254 ;
    
    client_print( victim, print_chat, "Player %s Knifed You From a Distance of %d Meter%s", fDistance, fDistance != 1 ? "s" : "" ) ;
    client_print( attacker, print_chat, "You Killed %s From a Distance of %d Meter%s", fDistance, fDistance != 1 ? "s" : "" ) ;
    
    return HAM_IGNORED ;
}

[administratora]

You Killed lololo From a Distance of 1066842124 Meters

[edon1337]

#include < amxmodx >
#include < fakemeta >
#include < hamsandwich >

public plugin_init( ) {

    register_plugin( "Knife Kill Distance", "1.0", "DoNii" ) ;

    RegisterHam( Ham_Killed, "player", "fw_HamKilledPost", 1 ) ;
}

public fw_HamKilledPost( victim, attacker, shouldgib ) {

    if( ! is_user_connected( attacker ) || ! is_user_connected( victim ) )
    return HAM_IGNORED ;

    if( get_user_weapon( attacker ) != CSW_KNIFE )
    return HAM_IGNORED ;

    new szNameAttacker[ 32 ], szNameVictim[ 32 ], Float:fVictimOrigin[ 3 ], Float:fAttackerOrigin[ 3 ], Float:fDistance ;
    get_user_name( attacker, szNameAttacker, charsmax( szNameAttacker ) ) ;
    get_user_name( victim, szNameVictim, charsmax( szNameVictim ) ) ;

    pev( victim, pev_origin, fVictimOrigin ) ;
    pev( attacker, pev_origin, fAttackerOrigin ) ;
    
    fDistance = get_distance_f( fAttackerOrigin, fVictimOrigin ) ;
    fDistance *= 0.0254 ;
    
    client_print( victim, print_chat, "Player %s Knifed You From a Distance of %d Meter%s", szNameAttacker, floatround( fDistance ), floatround( fDistance ) != 1 ? "s" : "" ) ;
    client_print( attacker, print_chat, "You Knifed %s From a Distance of %d Meter%s", szNameVictim, floatround( fDistance ), floatround( fDistance ) != 1 ? "s" : "" ) ;
    
    return HAM_IGNORED ;
}

[administratora]

Works but

PHP Code:

    client_print( victim, print_chat, "Player %s Knifed You From a Distance of %d Meter%s", floatround( fDistance ),  floatround( fDistance ) != 1 ? "s" : "" ) ;
    client_print( attacker, print_chat, "You Killed %s From a Distance of %d Meter%s", floatround( fDistance ),  floatround( fDistance ) != 1 ? "s" : "" ) ; 


for the victim I add , szName, but for the attacker is an empty space for %s, and I have seen other plugins that detects to the second number after , (for example 1.53 meters or 2.13 meters)

[administratora]

look like this http://imgur.com/Vqi5F1c

[edon1337]

Edited, the names are fixed, about the decimals I don't know sorry.

[administratora]

Thank you ! Idk but when I do it %.2f instead of %d it shows 0.00 only but with .00 maybe that will help u ?

[edon1337]

You're right. Try this.

#include < amxmodx >
#include < fakemeta >
#include < hamsandwich >

public plugin_init( ) {

    register_plugin( "Knife Kill Distance", "1.0", "DoNii" ) ;

    RegisterHam( Ham_Killed, "player", "fw_HamKilledPost", 1 ) ;
}

public fw_HamKilledPost( victim, attacker, shouldgib ) {

    if( ! is_user_connected( attacker ) || ! is_user_connected( victim ) )
    return HAM_IGNORED ;

    if( get_user_weapon( attacker ) != CSW_KNIFE )
    return HAM_IGNORED ;

    new szNameAttacker[ 32 ], szNameVictim[ 32 ], Float:fVictimOrigin[ 3 ], Float:fAttackerOrigin[ 3 ], Float:fDistance, Float:iDistance ;
    get_user_name( attacker, szNameAttacker, charsmax( szNameAttacker ) ) ;
    get_user_name( victim, szNameVictim, charsmax( szNameVictim ) ) ;

    pev( victim, pev_origin, fVictimOrigin ) ;
    pev( attacker, pev_origin, fAttackerOrigin ) ;
    
    fDistance = get_distance_f( fAttackerOrigin, fVictimOrigin ) ;
    
    iDistance = fDistance * 0.0254 ;
    
    client_print( victim, print_chat, "Player %s Knifed You From a Distance of %.2f Meter%s", szNameAttacker, iDistance, iDistance != 1 ? "s" : "" ) ;
    client_print( attacker, print_chat, "You Knifed %s From a Distance of %.2f Meter%s", szNameVictim, iDistance, iDistance != 1 ? "s" : "" ) ;
    
    return HAM_IGNORED ;
}

[SomewhereLost]

Originally Posted by administratora look like this http://imgur.com/Vqi5F1c

That picture is from Global Knife, no?