[kazya3]

I try to create a env_sprite when the weapon been dropped on the ground and set parent to the weapon.Here's some my code:

PHP Code:

public void OnClientPutInServer(int client)
{
    SDKHook(client, SDKHook_WeaponDrop, OnWeaponDrop);
}

public void OnWeaponDrop(int client, int weapon)
{
    if (!IsValidEntity(weapon) || GetClientTeam(client)!=2){return;}
    int sprite = CreateEntityByName("env_sprite");
    float  VecOrigin[3];
    GetEntPropVector(weapon, Prop_Send, "m_vecOrigin", VecOrigin);//cant get the position...:cry:
    DispatchKeyValueVector(sprite, "origin", VecOrigin);
    if(DEBUG)PrintToChatAll("[debug]origin: %.2f %.2f %.2f", VecOrigin[0], VecOrigin[1], VecOrigin[2]);//cant get the position...:cry:
    DispatchKeyValue(sprite, "model", "sprites/light_glow03.vmt");
    DispatchKeyValue(sprite, "rendermode", "9");
    DispatchKeyValue(sprite, "scale", "0.8");
    DispatchKeyValue(sprite, "spawnflags", "1");
    DispatchKeyValue(sprite, "fademaxdist", "3000");
    DispatchSpawn(sprite);
    SetEntPropEnt(sprite, Prop_Send, "m_hOwnerEntity", weapon);
    SetVariantString("!activator");
    AcceptEntityInput(sprite, "SetParent", weapon);
    SetVariantString("0 255 255");
    AcceptEntityInput(sprite, "Color");
} 


How can i get the position correctly?thanks

[HarryPotter]

Try

PHP Code:

GetEntPropVector(entity, Prop_Data, "m_vecAbsOrigin", VecOrigin); 


[kazya3]

Originally Posted by HarryPotter Try PHP Code: GetEntPropVector(entity, Prop_Data, "m_vecAbsOrigin", VecOrigin);

it works ,but the origin is a little strange. i think maybe because the weapon haven't been dropped when the event happens.
i tried the code:

PHP Code:

// 创建光晕
RequestFrame(NextFrame, weapon);

public void NextFrame (int weapon)
{
    float  VecOrigin[3];
    GetEntPropVector(weapon, Prop_Send, "m_vecOrigin", VecOrigin);
    if(DEBUG)PrintToChatAll("[debug]origin: %.2f %.2f %.2f", VecOrigin[0], VecOrigin[1], VecOrigin[2]);
    int sprite = CreateEntityByName("env_sprite");;
    DispatchKeyValueVector(sprite, "origin", VecOrigin);
    DispatchKeyValue(sprite, "model", "sprites/light_glow03.vmt");
    DispatchKeyValue(sprite, "rendermode", "9");
    DispatchKeyValue(sprite, "scale", "0.8");
    DispatchKeyValue(sprite, "spawnflags", "1");
    DispatchKeyValue(sprite, "fademaxdist", "3000");
    DispatchSpawn(sprite);
    SetEntPropEnt(sprite, Prop_Send, "m_hOwnerEntity", weapon);
    SetVariantString("!activator");
    AcceptEntityInput(sprite, "SetParent", weapon);
    SetVariantString("0 255 255");
    AcceptEntityInput(sprite, "Color");
} 


i get the weapon origin nextframe to confirm the weapon has left player's hand and maybe it's not the best way, but it works

[HarryPotter]

Originally Posted by kazya3 it works ,but the origin is a little strange. i think maybe because the weapon haven't been dropped when the event happens. i tried the code: PHP Code: // 创建光晕 RequestFrame(NextFrame, weapon); public void NextFrame (int weapon) {     float  VecOrigin[3];     GetEntPropVector(weapon, Prop_Send, "m_vecOrigin", VecOrigin);     if(DEBUG)PrintToChatAll("[debug]origin: %.2f %.2f %.2f", VecOrigin[0], VecOrigin[1], VecOrigin[2]);     int sprite = CreateEntityByName("env_sprite");;     DispatchKeyValueVector(sprite, "origin", VecOrigin);     DispatchKeyValue(sprite, "model", "sprites/light_glow03.vmt");     DispatchKeyValue(sprite, "rendermode", "9");     DispatchKeyValue(sprite, "scale", "0.8");     DispatchKeyValue(sprite, "spawnflags", "1");     DispatchKeyValue(sprite, "fademaxdist", "3000");     DispatchSpawn(sprite);     SetEntPropEnt(sprite, Prop_Send, "m_hOwnerEntity", weapon);     SetVariantString("!activator");     AcceptEntityInput(sprite, "SetParent", weapon);     SetVariantString("0 255 255");     AcceptEntityInput(sprite, "Color"); }  i get the weapon origin nextframe to confirm the weapon has left player's hand and maybe it's not the best way, but it works

Since you are using RequestFrame, you should pass the entityRef to the function because sometimes the entity may become invalid on next frame (was destoryed by some other plugin for example).

PHP Code:

RequestFrame(NextFrame, EntIndexToEntRef(weapon));


public void NextFrame (int entityRef)
{
    int weapon= EntRefToEntIndex(entityRef);

    if (weapon== INVALID_ENT_REFERENCE)
        return;

    ...
} 


Entity_References_(SourceMod)


when/why should i use EntRefToEntIndex/EntIndexToEntRef ?

[kazya3]

Originally Posted by HarryPotter Since you are using RequestFrame, you should pass the entityRef to the function because sometimes the entity may become invalid on next frame (was destoryed by some other plugin for example). PHP Code: RequestFrame(NextFrame, EntIndexToEntRef(weapon)); public void NextFrame (int entityRef) {     int weapon= EntRefToEntIndex(entityRef);     if (weapon== INVALID_ENT_REFERENCE)         return;     ... }  Entity_References_(SourceMod) when/why should i use EntRefToEntIndex/EntIndexToEntRef ?

learn a lot ，thank you.