[DruGzOG]

Does anyone know how to script a plugin to block a c4 from the terrorist? Or if there is a plugin where it restricts the c4 from being planted? Please Help :'(

[Exolent[jNr]]

PHP Code:

#include <amxmodx>
#include <fakemeta>

public plugin_init()
{
    register_plugin("Can't Plant C4", "0.1", "Exolent");
    register_forward(FM_CmdStart, "FwdCmdStart", 0);
    
    return PLUGIN_CONTINUE;
}

public FwdCmdStart(plr, uc_handle, seed)
{
    static clip, ammo;
    if( !is_user_alive(plr)
    || get_user_weapon(plr, clip, ammo) != CSW_C4 )
    {
        return FMRES_IGNORED;
    }
    
    new buttons = get_uc(uc_handle, UC_Buttons);
    if( buttons&IN_ATTACK )
    {
        buttons &= ~IN_ATTACK;
        set_uc(uc_handle, UC_Buttons, buttons);
        
        return FMRES_SUPERCEDE;
    }
    
    return FMRES_IGNORED;
} 


[DruGzOG]

Does this remove the C4?

[Exolent[jNr]]

If the terrorist has the c4 out, he cannot plant.

[DruGzOG]

Alright, Sweet Thanks +karma

[kramesa]

Can add cvar for enable/disable?

[Exolent[jNr]]

PHP Code:

#include <amxmodx>
#include <fakemeta>

new bool:gEnabled = true;

public plugin_init()
{
    register_plugin("Can't Plant C4", "0.1", "Exolent");
    
    register_concmd("c4_enable", "CmdEnable", ADMIN_RCON, "Allows C4 to be planted");
    register_concmd("c4_disable", "CmdDisable", ADMIN_RCON, "Stops C4 from being planted");
    
    register_forward(FM_CmdStart, "FwdCmdStart", 0);
}

public CmdEnable(id, level, cid)
{
    if(cmd_access(id, level, cid, 1))
    {
        setEnabled(id, true);
    }
    return PLUGIN_HANDLED;
}

public CmdDisable(id, level, cid)
{
    if(cmd_access(id, level, cid, 1))
    {
        setEnabled(id, false);
    }
    return PLUGIN_HANDLED;
}

setEnabled(id, bool:enabled)
{
    if(enabled == gEnabled)
    {
        console_print(id, "C4 is already %sabled.", enabled ? "en" : "dis");
    }
    else
    {
        gEnabled = enabled;
        console_print(id, "C4 is now %sabled.", enabled ? "en" : "dis");
    }
}

public FwdCmdStart(plr, uc_handle, seed)
{
    static clip, ammo;
    if( !gEnabled
    || !is_user_alive(plr)
    || get_user_weapon(plr, clip, ammo) != CSW_C4 )
    {
        return FMRES_IGNORED;
    }
    
    new buttons = get_uc(uc_handle, UC_Buttons);
    if( buttons&IN_ATTACK )
    {
        buttons &= ~IN_ATTACK;
        set_uc(uc_handle, UC_Buttons, buttons);
        
        return FMRES_SUPERCEDE;
    }
    
    return FMRES_IGNORED;
} 


[Exolent[jNr]]

Originally Posted by kramesa Dont works

You realize that it's not a cvar, but a command. Right?

[kramesa]

Man, sorry, i used c4_enable for enables plant c4 -.-

thanks.

[ConnorMcLeod]

OMG don't hook CmdStart for this lol !!!

Set g_bCanPlantC4 anywhere and under any conditions you want :

PHP Code:

#include <amxmodx>
#include <fakemeta>
#include <hamsandwich>
// #include <cstrike>

#define VERSION "0.0.1"
#define PLUGIN ""

const XO_WEAPON = 4

const m_pPlayer = 41
const m_flNextPrimaryAttack = 46

new bool:g_bCanPlantC4

public plugin_init()
{
    register_plugin(PLUGIN, VERSION, "ConnorMcLeod")
    RegisterHam(Ham_Weapon_PrimaryAttack, "weapon_c4", "CC4_PrimaryAttack")
}

public CC4_PrimaryAttack( iC4 )
{
    if( !g_bCanPlantC4 )
    {
        new id = get_pdata_cbase(iC4, m_pPlayer, XO_WEAPON)
        client_print(id, print_chat, "C4 is actually disabled !!")
        set_pdata_float(iC4, m_flNextPrimaryAttack, 1.0, XO_WEAPON)
        return HAM_SUPERCEDE
    }
    return HAM_IGNORED
}